Set m4 directory.
[util-vserver.git] / configure.ac
1 dnl $Id$
2
3 dnl Copyright (C) 2003,2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
4 dnl
5 dnl This program is free software; you can redistribute it and/or modify
6 dnl it under the terms of the GNU General Public License as published by
7 dnl the Free Software Foundation; either version 2, or (at your option)
8 dnl any later version.
9 dnl
10 dnl This program is distributed in the hope that it will be useful,
11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 dnl GNU General Public License for more details.
14 dnl
15 dnl You should have received a copy of the GNU General Public License
16 dnl along with this program; if not, write to the Free Software
17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18 dnl
19 dnl
20 dnl As a special exception to the GNU General Public License, if you
21 dnl distribute this file as part of a program that contains a configuration
22 dnl script generated by Autoconf, you may include it under the same
23 dnl distribution terms that you use for the rest of that program.
24 dnl
25
26 AC_PREREQ(2.57)
27 AC_INIT(util-vserver, 0.30.215, vserver@list.linux-vserver.org)
28 AC_CONFIG_SRCDIR([src/capchroot.c])
29 AC_CONFIG_HEADER([config.h])
30 AC_CONFIG_MACRO_DIR([m4])
31
32 AM_INIT_AUTOMAKE([1.9 gnits dist-bzip2 subdir-objects])
33 AM_MAINTAINER_MODE
34
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37
38 AC_SUBST(GPG_KEY, "0xFFD316AC53ACA43A!")
39
40 # Checks for programs.
41 AC_PROG_CXX
42 AC_PROG_CC
43 AC_PROG_INSTALL
44 AC_PROG_LN_S
45 AM_PROG_CC_C_O
46 PKG_PROG_PKG_CONFIG
47 ENSC_CXXCOMPILER
48 ENSC_C99COMPILER
49
50 ENSC_SET_SEARCHPATH([$PATH:/sbin:/usr/sbin:/usr/local/sbin])
51 ENSC_PATHPROG_STANDARD_TOOLS
52
53 ENSC_PATHPROG(IP,        ip,,      [Usually, this tool is shipped in the 'iproute' or 'iproute2' package of your distribution])
54 ENSC_PATHPROG(IPTABLES,  iptables)
55 ENSC_PATHPROG(MODPROBE,  modprobe)
56 ENSC_PATHPROG(NAMEIF,    nameif)
57 ENSC_PATHPROG(NOHUP,     nohup)
58 ENSC_PATHPROG(RMMOD,     rmmod)
59 ENSC_PATHPROG(VCONFIG,   vconfig,, [See http://www.candelatech.com/~greear/vlan.html; usually this tool is shipped in the 'vconfig' or 'vlan' package of your distribution])
60 ENSC_PATHPROG(WGET,      wget)
61 ENSC_PATHPROG(IONICE,    ionice,  [],  [This is usually shipped in the 'util-linux(-ng)' or 'schedutils' package])
62 ENSC_PATHPROG(FILE,      file,    [file])
63 ENSC_PATHPROG(GZIP,      gzip,    [gzip])
64 ENSC_PATHPROG(BZIP2,     bzip2,   [bzip2])
65 ENSC_PATHPROG(CPIO,      cpio,    [cpio])
66 ENSC_PATHPROG(RESTORE,   restore, [restore])
67 ENSC_PATHPROG(RSYNC,     rsync,   [rsync])
68 ENSC_PATHPROG(STRACE,    strace,  [strace])
69 ENSC_PATHPROG(FSCK,      fsck)
70 ENSC_PATHPROG(FIND,      find)
71
72 ENSC_PATHPROG(DOXYGEN,   doxygen,  [:])
73 ENSC_PATHPROG(XSLTP,     xsltp,    [:])
74 ENSC_PATHPROG(XSLTPROC,  xsltproc, [:])
75
76
77 AM_CONDITIONAL(HAVE_XSLTP,    test "$XSLTP"    != ':')
78 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != ':')
79
80 if test x"$prefix" = x/; then
81         prefix=
82 fi
83
84 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
85 ENSC_CHECK_CXX_FLAG([-ansi   -Wall -pedantic -W -fmessage-length=0])
86
87 AC_MSG_CHECKING([whether to enable extra optimizations])
88 AC_ARG_ENABLE([extra-optimizations],
89               [AC_HELP_STRING([--disable-extra-optimizations],
90                               [disable certain extra optimizations (default: no)])],
91               [case "$enableval" in
92                   (yes) use_extra_optimizations=1;;
93                   (no)  use_extra_optimizations=;;
94                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--disable-extra-optimizations']);;
95                esac],
96               [use_extra_optimizations=1])
97
98 if test x"$use_extra_optimizations" = x; then
99         AC_MSG_RESULT(no)
100 else
101         AC_MSG_RESULT(yes)
102         ENSC_CHECK_CC_FLAG([-funit-at-a-time])
103         ENSC_CHECK_CXX_FLAG([-funit-at-a-time])
104 fi
105
106 AC_MSG_CHECKING([whether to enable debug-code in library])
107 AC_ARG_ENABLE([lib-debug],
108               [AC_HELP_STRING([--enable-lib-debug],
109                               [enable additional debug code in library (default: no)])],
110               [case "$enableval" in
111                   (yes) use_lib_debug=1;;
112                   (no)  use_lib_debug=;;
113                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
114                esac],
115               [ use_lib_debug= ])
116
117 if test x"$use_lib_debug" = x; then
118         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
119         AC_MSG_RESULT(no)
120 else
121         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
122         AC_MSG_RESULT(yes)
123 fi
124
125 AC_MSG_CHECKING([whether to enable expensive tests])
126 AC_ARG_ENABLE([expensive-tests],
127               [AC_HELP_STRING([--enable-expensive-tests],
128                               [disable tests which might be expensive on some systems (default: no)])],
129               [case "$enableval" in
130                  (yes|no)  use_expensive_tests=$enableval;;
131                  (*)       AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-expensive-tests']);;
132                esac],
133               [ use_expensive_tests=no ])
134 AC_MSG_RESULT($use_expensive_tests)
135
136 AC_SUBST(ENSC_USE_EXPENSIVE_TESTS, "$use_expensive_tests")
137
138
139 ENSC_CHECK_PERSONALITY_FLAGS
140
141 AC_ARG_VAR(CC, [The C compiler])
142
143 ENSC_INITRDDIR(initrddir)
144 ENSC_RELEASE(RELEASE_CPPFLAGS)
145
146 # HACK: This needs to be before ENSC_DIETLIBC_NEED_COMPAT, or the alternative
147 # syscalls will never be enabled for glibc.
148 ENSC_SYSCALLNR(vserver,273,[lib/syscall-fallback.h])
149 ENSC_SYSCALL
150
151 dnl ###########################
152 dnl
153 dnl {some dietlibc related tests
154 dnl
155
156 case $host_cpu in
157         (i*86|athlon)   min_diet_ver=0.25;;
158         (ia64|hppa*)    min_diet_ver=0.29;;
159         (sparc*)        min_diet_ver=0.30;;
160         (x86_64)        min_diet_ver=0.27;;
161         (*)             min_diet_ver=0.28;;
162 esac
163
164 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC, [$min_diet_ver])
165
166 if test x"$ensc_have_dietlibc" = xno; then
167         AC_MSG_WARN([***                                                         ***])
168         AC_MSG_WARN([*** it is strongly recommended to link util-vserver against ***])
169         AC_MSG_WARN([*** dietlibc;  glibc's NSS functions are very unreliable in ***])
170         AC_MSG_WARN([*** chroot() environments,  so you have to  expect problems ***])
171         AC_MSG_WARN([*** there.                                                  ***])
172         AC_MSG_WARN([***                                                         ***])
173         AM_CONDITIONAL(USE_DIETLIBC_COMPAT, false)
174 else
175         # HACK: libtool does not have cmdline options to build only
176         # dynamic libraries; this can be done with the
177         # '--disable-static' ./configure option only.  As our static
178         # libraries will be build with dietlibc, we have to do set
179         # this option which is evaluated by 'AC_PROG_LIBTOOL'
180         # below.  Therefore, this macro must not be called earlier.
181         enable_static=no
182
183         ENSC_DIETLIBC_NEED_COMPAT(USE_DIETLIBC_COMPAT)
184 fi
185
186 AM_CONDITIONAL(ENSC_USE_DIETLIBC, test x"$ensc_have_dietlibc" = xyes)
187 AM_CONDITIONAL(ENSC_USE_GLIBC,    true)
188
189 # HACK: see comments at 'enable_static' above
190 AC_PROG_LIBTOOL
191 dnl
192 dnl dietlibc stuff ends here}
193 dnl
194 dnl ##########################
195
196
197 ENSC_UV_VROOTDIR(vserverdir)
198 ENSC_CHANGELOG
199
200
201 dnl ##########################
202 dnl
203 dnl {Check whether to use external kernel headers
204 dnl
205 AC_MSG_CHECKING([whether to use internal kernel headers])
206 AC_ARG_ENABLE([internal-headers],
207               [AC_HELP_STRING([--disable-internal-headers],
208                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
209               [case "$enableval" in
210                   (yes|no) ;;
211                   (*)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
212                esac],
213               [enable_internal_headers=yes])
214
215 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
216 AC_MSG_RESULT([$enable_internal_headers])
217 dnl
218 dnl the check regarding external kernel headers ends here}
219 dnl
220 dnl ##########################
221
222 dnl ##########################
223 dnl
224 dnl {Check for the APIs to be used
225 dnl
226 AH_TEMPLATE(VC_ENABLE_API_COMPAT,   [Enable support for compatibility syscall API])
227 AH_TEMPLATE(VC_ENABLE_API_LEGACY,   [Enable support for old, /proc parsing API])
228 AH_TEMPLATE(VC_ENABLE_API_V11,      [Enable support for API of vserver 1.1.x])
229 AH_TEMPLATE(VC_ENABLE_API_FSCOMPAT, [Enable support for filesystem compatibility API])
230 AH_TEMPLATE(VC_ENABLE_API_V13OBS,   [Enable support for some obsoleted API of vserver 1.3.x])
231 AH_TEMPLATE(VC_ENABLE_API_V13,      [Enable support for API of vserver 1.3.x])
232 AH_TEMPLATE(VC_ENABLE_API_NET,      [Enable support for network context API])
233 AH_TEMPLATE(VC_ENABLE_API_V21,      [Enable support for API of vserver 2.1.x])
234 AH_TEMPLATE(VC_ENABLE_API_V22,      [Enable support for API of vserver 2.2.x])
235 AH_TEMPLATE(VC_ENABLE_API_V23,      [Enable support for API of vserver 2.3.x])
236 AH_TEMPLATE(VC_ENABLE_API_NETV2,    [Enable support for new networking API])
237 AH_TEMPLATE(VC_ENABLE_API_OLDPROC,  [Enable API for a backward compatible /proc parsing])
238 AH_TEMPLATE(VC_ENABLE_API_OLDUTS,   [Enable API for a backward compatible uts handling])
239
240 AC_MSG_CHECKING([for supported APIs])
241 AC_ARG_ENABLE([apis],
242               [AC_HELP_STRING([--enable-apis=APIS],
243                               [enable support for the given apis; possible values are: legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2 ALL,NOLEGACY (default: v13,net,v21,v22,v23,netv2)])],
244               [],
245               [enable_apis=v13,net,v21,v22,v23,netv2])
246
247 test x"$enable_apis" != xALL      || enable_apis='legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2'
248 test x"$enable_apis" != xNOLEGACY || enable_apis='compat,v11,fscompat,v13,net,v21,v22,v23,netv2'
249 enable_api_oldproc=
250 enable_api_olduts=
251
252 echo $enable_apis | sed 's/,/\n/g' | while read i; do
253         case "$i" in
254                 (compat)        AC_DEFINE(VC_ENABLE_API_COMPAT,   1)
255                                 enable_api_oldproc=${enable_api_oldproc:-1}
256                                 enable_api_olduts=${enable_api_olduts:-1}
257                                 ;;
258                 (legacy)        AC_DEFINE(VC_ENABLE_API_LEGACY,   1)
259                                 enable_api_oldproc=${enable_api_oldproc:-1}
260                                 enable_api_olduts=${enable_api_olduts:-1}
261                                 ;;
262                 (v11)           AC_DEFINE(VC_ENABLE_API_V11,      1)
263                                 enable_api_oldproc=${enable_api_oldproc:-1}
264                                 enable_api_olduts=${enable_api_olduts:-1}
265                                 ;;
266                 (fscompat)      AC_DEFINE(VC_ENABLE_API_FSCOMPAT, 1);;
267                 (v13obs)        AC_DEFINE(VC_ENABLE_API_V13OBS,   1)
268                                 AC_DEFINE(VC_ENABLE_API_V13,      1);;
269                 (v13)           AC_DEFINE(VC_ENABLE_API_V13,      1);;
270                 (net)           AC_DEFINE(VC_ENABLE_API_NET,      1);;
271                 (v21)           AC_DEFINE(VC_ENABLE_API_V21,      1);;
272                 (v22)           AC_DEFINE(VC_ENABLE_API_V22,      1);;
273                 (v23)           AC_DEFINE(VC_ENABLE_API_V23,      1);;
274                 (netv2)         AC_DEFINE(VC_ENABLE_API_NETV2,    1);;
275                 (oldproc)       enable_api_oldproc=2;;
276                 (olduts)        enable_api_olduts=2;;
277                 (*)             AC_MSG_ERROR(['$i' is not a supported API]);;
278         esac
279 done
280 if test x"$enable_api_oldproc" != x; then
281         AC_DEFINE(VC_ENABLE_API_OLDPROC, 1)
282         test x"$enable_api_oldproc" != x2 && enable_apis="$enable_apis,oldproc"
283 fi
284 if test x"$enable_api_olduts" != x; then
285         AC_DEFINE(VC_ENABLE_API_OLDUTS, 1)
286         test x"$enable_api_olduts" != x2 && enable_apis="$enable_apis,olduts"
287 fi
288 AC_MSG_RESULT([$enable_apis])
289 dnl
290 dnl the check for used APIs ends here}
291 dnl
292 dnl ##########################
293
294
295 ENSC_CHECK_EXT2FS_HEADER
296 AC_CHECK_FUNCS([vserver])
297 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
298 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
299 AC_CHECK_TYPES(nid_t,,,[#include <sys/types.h>])
300 AC_CHECK_TYPES(tag_t,,,[#include <sys/types.h>])
301
302 AC_CHECK_HEADERS([sys/capability.h])
303
304 dnl vlogin might need -lutil
305 if test x"$ensc_have_dietlibc" = xno; then
306         AC_CHECK_FUNC([openpty],, [AC_CHECK_LIB([util], [openpty],, [AC_MSG_ERROR([
307 ****
308 **** openpty could not be found
309 ****])])])
310 fi
311
312
313 dnl ########################
314 dnl
315 dnl {crypto stuff
316 dnl
317 AC_ARG_WITH(crypto-api,
318             AC_HELP_STRING([--with-crypto-api=API],
319                            [select crypto api to be used; possible values are `none', `nss', `beecrypt', `auto' (default:auto)]),
320             [case $withval in
321                 (none|nss|beecrypt|auto)        ensc_crypto_api=$withval;;
322                 (yes)                           ensc_crypto_api=auto;;
323                 (no)                            ensc_crypto_api=none;;
324                 (*)     AC_MSG_ERROR([invalid crypto-api value, only none,nss,beecrypt,auto are supported]);;
325              esac],[ensc_crypto_api=auto])
326
327
328 dnl Now, check for matching crypto api. When selected 'auto', the
329 dnl first matching one wins
330
331 dnl ########################
332 dnl
333 dnl {check for beecrypt
334 dnl
335 case $ensc_crypto_api in
336 (auto|beecrypt)
337 if test x"$ensc_cv_c99_c99compiler" = xyes; then
338         ensc_have_beecrypt=yes
339
340         if test x"$ensc_have_beecrypt" = xyes; then
341                 AC_CHECK_HEADER([beecrypt/beecrypt.h], [ : ],
342                                 [ ensc_have_beecrypt=no ])
343         fi
344
345         if test x"$ensc_have_beecrypt" = xyes; then
346                 AC_CHECK_LIB(beecrypt, hashFunctionContextInit, [ : ],
347                              [ ensc_have_beecrypt=no ])
348         fi
349 else
350         ensc_have_beecrypt=no
351 fi;;
352 esac
353
354 case $ensc_crypto_api in
355 (auto)          if test x"$ensc_have_beecrypt"  = xyes; then
356                         AC_MSG_NOTICE([using beecrypt as crypto api])
357                         ensc_crypto_api=beecrypt
358                 fi;;
359 (beecrypt)      if test x"$ensc_have_beecrypt" != xyes; then
360                         AC_MSG_ERROR([beecrypt crypto api not found])
361                 fi;;
362 esac
363
364 AM_CONDITIONAL(ENSC_HAVE_BEECRYPT, test x"$ensc_have_beecrypt" = xyes)
365 AM_CONDITIONAL(ENSC_CAN_BEECRYPT_WITH_DIETLIBC, false)
366 dnl
367 dnl beecrypt stuff ends here}
368 dnl
369 dnl ########################
370
371
372 dnl ########################
373 dnl
374 dnl {check for nss
375 dnl
376
377 case $ensc_crypto_api in
378 (nss)   PKG_CHECK_MODULES(NSS, nss);;
379 (auto)  PKG_CHECK_MODULES(NSS, nss, [
380                 AC_MSG_NOTICE([using NSS as crypto api])
381                 ensc_crypto_api=nss]);;
382 esac
383
384 dnl
385 dnl nss stuff ends here}
386 dnl
387 dnl ########################
388
389 case $ensc_crypto_api in
390 (beecrypt)
391         ENSC_HAVE_CRYPTO=true
392         ENSC_CRYPTO_API=ENSC_CRYPTO_API_BEECRYPT
393         ENSC_CRYPTO_CFLAGS=
394         ENSC_CRYPTO_LIB=-lbeecrypt
395         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
396         ;;
397
398 (nss)
399         ENSC_HAVE_CRYPTO=true
400         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NSS
401         ENSC_CRYPTO_CFLAGS=$NSS_CFLAGS
402         ENSC_CRYPTO_LIB=$NSS_LIBS
403         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
404         ;;
405
406 (none|auto)
407         ENSC_HAVE_CRYPTO=false
408         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NONE
409         ENSC_CRYPTO_CFLAGS=
410         ENSC_CRYPTO_LIB=
411         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
412
413         AC_MSG_WARN([No crypto api found/select. This will disable the build of 'vhashify'])
414         ;;
415
416 (*)     AC_MSG_ERROR([internal error])
417 esac
418
419 AM_CONDITIONAL(ENSC_HAVE_CRYPTO, $ENSC_HAVE_CRYPTO)
420 AM_CONDITIONAL(ENSC_CAN_CRYPTO_WITH_DIETLIBC, $ENSC_CAN_CRYPTO_WITH_DIETLIBC)
421 AC_SUBST(ENSC_CRYPTO_CFLAGS, $ENSC_CRYPTO_CFLAGS)
422 AC_SUBST(ENSC_CRYPTO_LIB,    $ENSC_CRYPTO_LIB)
423 AC_DEFINE_UNQUOTED(ENSC_CRYPTO_API, $ENSC_CRYPTO_API, [Used crypto API])
424
425 dnl
426 dnl crypto stuff ends here}
427 dnl
428 dnl ########################
429
430
431 dnl Check what distro this is, use Gentoo initscripts if appropriate
432 AC_MSG_CHECKING([for host initscripts])
433 AC_ARG_WITH(initscripts, AC_HELP_STRING([--with-initscripts=TYPE], [force host initscripts; valid values are 'gentoo' and 'sysv' (default: guess)]), [
434         case "$withval" in
435         gentoo) ensc_with_init=gentoo;;
436         sysv)   ensc_with_init=sysv;;
437         *)      AC_MSG_ERROR([invalid initscripts value, only gentoo and sysv are supported]);;
438         esac
439         ], [
440         if test -e /etc/gentoo-release; then
441                 ensc_with_init=gentoo
442         else
443                 ensc_with_init=sysv
444         fi
445         ])
446 AC_MSG_RESULT([$ensc_with_init])
447 AM_CONDITIONAL(HAVE_GENTOO_INIT, test x"$ensc_with_init" = xgentoo)
448 AM_CONDITIONAL(HAVE_SYSV_INIT, test x"$ensc_with_init" = xsysv)
449
450
451 dnl ########################
452 dnl Check for Python
453
454 ensc_have_python=yes
455 AM_PATH_PYTHON([2.4],, [:])
456 if test "x$PYTHON" = x:; then
457         ensc_have_python=no
458 fi
459 if test x$ensc_have_python = xyes; then
460         PYTHON_CFLAGS=-I`$PYTHON -c 'from distutils.sysconfig import get_python_inc; print get_python_inc(1)'`
461         PYTHON_LDFLAGS=-L`$PYTHON -c 'from distutils.sysconfig import get_python_lib; print get_python_lib(1)'`
462         AC_SUBST(PYTHON_CFLAGS)
463         AC_SUBST(PYTHON_LDFLAGS)
464 else
465         ensc_have_python=no
466 fi
467 AC_PATH_PROG([CTAGS], [ctags], [no])
468 if test "x$CTAGS" = xno; then
469         ensc_have_python=no
470 fi
471 AM_CONDITIONAL([HAVE_PYTHON], [test x$ensc_have_python = xyes])
472
473 dnl Python stuff ends here
474 dnl ########################
475
476
477 dnl ########################
478 dnl Library versioning
479
480 ensc_have_versioning=yes
481 AC_ARG_ENABLE(versioning, AC_HELP_STRING([--disable-versioning], [Disable library versioning]), [ensc_have_versioning="$enableval"])
482 AM_CONDITIONAL([HAVE_VERSIONING], [test "x$ensc_have_versioning" = xyes])
483 if test "x$ensc_have_versioning" = xyes; then
484         AC_DEFINE([HAVE_VERSIONING], [1], [Define this to use library versioning])
485 fi
486
487 dnl /Library versioning
488 dnl ########################
489
490
491 dnl BIG HACK! Do some autodetection here!
492 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
493
494 if false; then
495         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
496 fi
497
498 AC_DEFINE(_FILE_OFFSET_BITS, [64], [Use 64bit interface for filesystem operations])
499
500 dnl ########################
501 dnl
502 dnl {The final info-page
503 dnl
504 ensc_cxx_affected=" (affected: vbuild, vcheck)"
505 ensc_c99_affected=" (affected: vunify, vcopy, vhashify, vdlimit)"
506 ensc_diet_msg=" (you have been warned)"
507 ensc_diet_version_msg=" ($ensc_version_dietlibc)"
508 ensc_diet_compat_msg=" (using -lcompat)"
509 test x"$ensc_cv_cxx_cxxcompiler"    = xno || ensc_cxx_affected=
510 test x"$ensc_cv_c99_c99compiler"    = xno || ensc_c99_affected=
511 test x"$ensc_have_dietlibc"         = xno || ensc_diet_msg=
512 test x"$ensc_version_dietlibc"     != x   || ensc_diet_version_msg=
513 test x"$ensc_have_dietlibc$ensc_cv_c_dietlibc_compat" = xyesyes || ensc_diet_compat_msg=
514
515 AH_BOTTOM([#include "compat.h"
516 ])
517 AC_CONFIG_COMMANDS_PRE([
518                         FEATURES_TXT="\
519 Features:
520                        CC: $CC, $($CC   --version | sed -e '1p;d')
521                       CXX: $CXX, $($CXX --version | sed -e '1p;d')
522                  CPPFLAGS: '$CPPFLAGS'
523                    CFLAGS: '$CFLAGS'
524                  CXXFLAGS: '$CXXFLAGS'
525                build/host: $build/$host
526              Use dietlibc: $ensc_have_dietlibc$ensc_diet_version_msg$ensc_diet_msg$ensc_diet_compat_msg
527        Build C++ programs: $ensc_cv_cxx_cxxcompiler$ensc_cxx_affected
528        Build C99 programs: $ensc_cv_c99_c99compiler$ensc_c99_affected
529            Available APIs: $enable_apis
530             ext2fs Source: $ensc_cv_test_ext2fs_header
531     syscall(2) invocation: $with_syscall
532       vserver(2) syscall#: $ensc_cv_value_syscall_vserver
533                crypto api: $ensc_crypto_api
534           python bindings: $ensc_have_python
535    use library versioning: $ensc_have_versioning
536
537 Paths:
538                    prefix: $prefix
539         sysconf-Directory: $sysconfdir
540             cfg-Directory: $sysconfdir/vservers
541          initrd-Directory: $initrddir
542        pkgstate-Directory: $localstatedir/run/vservers
543           vserver-Rootdir: $vserverdir
544 "
545                         echo "$FEATURES_TXT" >FEATURES.txt
546                         ])
547 dnl
548 dnl final info-page ends here}
549 dnl
550 dnl ########################
551
552 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile lib/apidoc/Doxyfile])
553 AC_OUTPUT
554
555 AC_MSG_NOTICE([
556
557 $PACKAGE_STRING
558
559 $FEATURES_TXT])