Check for find in configure since it may be a symlink.
[util-vserver.git] / configure.ac
1 dnl $Id$
2
3 dnl Copyright (C) 2003,2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
4 dnl  
5 dnl This program is free software; you can redistribute it and/or modify
6 dnl it under the terms of the GNU General Public License as published by
7 dnl the Free Software Foundation; either version 2, or (at your option)
8 dnl any later version.
9 dnl  
10 dnl This program is distributed in the hope that it will be useful,
11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 dnl GNU General Public License for more details.
14 dnl  
15 dnl You should have received a copy of the GNU General Public License
16 dnl along with this program; if not, write to the Free Software
17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18 dnl  
19 dnl  
20 dnl As a special exception to the GNU General Public License, if you
21 dnl distribute this file as part of a program that contains a configuration
22 dnl script generated by Autoconf, you may include it under the same
23 dnl distribution terms that you use for the rest of that program.
24 dnl  
25
26 AC_PREREQ(2.57)
27 AC_INIT(util-vserver, 0.30.215, vserver@list.linux-vserver.org)
28 AC_CONFIG_SRCDIR([src/capchroot.c])
29 AC_CONFIG_HEADER([config.h])
30
31 AM_INIT_AUTOMAKE([1.9 gnits dist-bzip2 subdir-objects])
32 AM_MAINTAINER_MODE
33
34 AC_CANONICAL_BUILD
35 AC_CANONICAL_HOST
36
37 AC_SUBST(GPG_KEY, "0xFFD316AC53ACA43A!")
38
39 # Checks for programs.
40 AC_PROG_CXX
41 AC_PROG_CC
42 AC_PROG_INSTALL
43 AC_PROG_LN_S
44 AM_PROG_CC_C_O
45 PKG_PROG_PKG_CONFIG
46 ENSC_CXXCOMPILER
47 ENSC_C99COMPILER
48
49 ENSC_SET_SEARCHPATH([$PATH:/sbin:/usr/sbin:/usr/local/sbin])
50 ENSC_PATHPROG_STANDARD_TOOLS
51
52 ENSC_PATHPROG(IP,        ip,,      [Usually, this tool is shipped in the 'iproute' or 'iproute2' package of your distribution])
53 ENSC_PATHPROG(IPTABLES,  iptables)
54 ENSC_PATHPROG(MODPROBE,  modprobe)
55 ENSC_PATHPROG(NAMEIF,    nameif)
56 ENSC_PATHPROG(NOHUP,     nohup)
57 ENSC_PATHPROG(RMMOD,     rmmod)
58 ENSC_PATHPROG(VCONFIG,   vconfig,, [See http://www.candelatech.com/~greear/vlan.html; usually this tool is shipped in the 'vconfig' or 'vlan' package of your distribution])
59 ENSC_PATHPROG(WGET,      wget)
60 ENSC_PATHPROG(IONICE,    ionice,  [],  [This is usually shipped in the 'util-linux(-ng)' or 'schedutils' package])
61 ENSC_PATHPROG(FILE,      file,    [file])
62 ENSC_PATHPROG(GZIP,      gzip,    [gzip])
63 ENSC_PATHPROG(BZIP2,     bzip2,   [bzip2])
64 ENSC_PATHPROG(CPIO,      cpio,    [cpio])
65 ENSC_PATHPROG(RESTORE,   restore, [restore])
66 ENSC_PATHPROG(RSYNC,     rsync,   [rsync])
67 ENSC_PATHPROG(STRACE,    strace,  [strace])
68 ENSC_PATHPROG(FSCK,      fsck)
69 ENSC_PATHPROG(FIND,      find)
70
71 ENSC_PATHPROG(DOXYGEN,   doxygen,  [:])
72 ENSC_PATHPROG(XSLTP,     xsltp,    [:])
73 ENSC_PATHPROG(XSLTPROC,  xsltproc, [:])
74
75
76 AM_CONDITIONAL(HAVE_XSLTP,    test "$XSLTP"    != ':')
77 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != ':')
78
79 if test x"$prefix" = x/; then
80         prefix=
81 fi      
82
83 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
84 ENSC_CHECK_CXX_FLAG([-ansi   -Wall -pedantic -W -fmessage-length=0])
85
86 AC_MSG_CHECKING([whether to enable extra optimizations])
87 AC_ARG_ENABLE([extra-optimizations],
88               [AC_HELP_STRING([--disable-extra-optimizations],
89                               [disable certain extra optimizations (default: no)])],
90               [case "$enableval" in
91                   (yes) use_extra_optimizations=1;;
92                   (no)  use_extra_optimizations=;;
93                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--disable-extra-optimizations']);;
94                esac],
95               [use_extra_optimizations=1])
96
97 if test x"$use_extra_optimizations" = x; then
98         AC_MSG_RESULT(no)
99 else
100         AC_MSG_RESULT(yes)
101         ENSC_CHECK_CC_FLAG([-funit-at-a-time])
102         ENSC_CHECK_CXX_FLAG([-funit-at-a-time])
103 fi
104
105 AC_MSG_CHECKING([whether to enable debug-code in library])
106 AC_ARG_ENABLE([lib-debug],
107               [AC_HELP_STRING([--enable-lib-debug],
108                               [enable additional debug code in library (default: no)])],
109               [case "$enableval" in
110                   (yes) use_lib_debug=1;;
111                   (no)  use_lib_debug=;;
112                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
113                esac],
114               [ use_lib_debug= ])
115
116 if test x"$use_lib_debug" = x; then
117         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
118         AC_MSG_RESULT(no)
119 else
120         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
121         AC_MSG_RESULT(yes)
122 fi
123
124 AC_MSG_CHECKING([whether to enable expensive tests])
125 AC_ARG_ENABLE([expensive-tests],
126               [AC_HELP_STRING([--enable-expensive-tests],
127                               [disable tests which might be expensive on some systems (default: no)])],
128               [case "$enableval" in
129                  (yes|no)  use_expensive_tests=$enableval;;
130                  (*)       AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-expensive-tests']);;
131                esac],
132               [ use_expensive_tests=no ])
133 AC_MSG_RESULT($use_expensive_tests)
134
135 AC_SUBST(ENSC_USE_EXPENSIVE_TESTS, "$use_expensive_tests")
136
137
138 ENSC_CHECK_PERSONALITY_FLAGS
139
140 AC_ARG_VAR(CC, [The C compiler])
141
142 ENSC_INITRDDIR(initrddir)
143 ENSC_RELEASE(RELEASE_CPPFLAGS)
144
145 # HACK: This needs to be before ENSC_DIETLIBC_NEED_COMPAT, or the alternative
146 # syscalls will never be enabled for glibc.
147 ENSC_SYSCALLNR(vserver,273,[lib/syscall-fallback.h])
148 ENSC_SYSCALL
149
150 dnl ###########################
151 dnl
152 dnl {some dietlibc related tests
153 dnl
154
155 case $host_cpu in
156         (i*86|athlon)   min_diet_ver=0.25;;
157         (ia64|hppa*)    min_diet_ver=0.29;;
158         (sparc*)        min_diet_ver=0.30;;
159         (x86_64)        min_diet_ver=0.27;;
160         (*)             min_diet_ver=0.28;;
161 esac
162
163 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC, [$min_diet_ver])
164
165 if test x"$ensc_have_dietlibc" = xno; then
166         AC_MSG_WARN([***                                                         ***])
167         AC_MSG_WARN([*** it is strongly recommended to link util-vserver against ***])
168         AC_MSG_WARN([*** dietlibc;  glibc's NSS functions are very unreliable in ***])
169         AC_MSG_WARN([*** chroot() environments,  so you have to  expect problems ***])
170         AC_MSG_WARN([*** there.                                                  ***])
171         AC_MSG_WARN([***                                                         ***])
172         AM_CONDITIONAL(USE_DIETLIBC_COMPAT, false)
173 else
174         # HACK: libtool does not have cmdline options to build only
175         # dynamic libraries; this can be done with the
176         # '--disable-static' ./configure option only.  As our static
177         # libraries will be build with dietlibc, we have to do set
178         # this option which is evaluated by 'AC_PROG_LIBTOOL'
179         # below.  Therefore, this macro must not be called earlier.
180         enable_static=no
181
182         ENSC_DIETLIBC_NEED_COMPAT(USE_DIETLIBC_COMPAT)
183 fi
184
185 AM_CONDITIONAL(ENSC_USE_DIETLIBC, test x"$ensc_have_dietlibc" = xyes)
186 AM_CONDITIONAL(ENSC_USE_GLIBC,    true)
187
188 # HACK: see comments at 'enable_static' above
189 AC_PROG_LIBTOOL
190 dnl
191 dnl dietlibc stuff ends here}
192 dnl
193 dnl ##########################
194
195
196 ENSC_UV_VROOTDIR(vserverdir)
197 ENSC_CHANGELOG
198
199
200 dnl ##########################
201 dnl
202 dnl {Check whether to use external kernel headers
203 dnl
204 AC_MSG_CHECKING([whether to use internal kernel headers])
205 AC_ARG_ENABLE([internal-headers],
206               [AC_HELP_STRING([--disable-internal-headers],
207                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
208               [case "$enableval" in
209                   (yes|no) ;;
210                   (*)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
211                esac],
212               [enable_internal_headers=yes])
213
214 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
215 AC_MSG_RESULT([$enable_internal_headers])
216 dnl
217 dnl the check regarding external kernel headers ends here}
218 dnl
219 dnl ##########################
220
221 dnl ##########################
222 dnl
223 dnl {Check for the APIs to be used
224 dnl
225 AH_TEMPLATE(VC_ENABLE_API_COMPAT,   [Enable support for compatibility syscall API])
226 AH_TEMPLATE(VC_ENABLE_API_LEGACY,   [Enable support for old, /proc parsing API])
227 AH_TEMPLATE(VC_ENABLE_API_V11,      [Enable support for API of vserver 1.1.x])
228 AH_TEMPLATE(VC_ENABLE_API_FSCOMPAT, [Enable support for filesystem compatibility API])
229 AH_TEMPLATE(VC_ENABLE_API_V13OBS,   [Enable support for some obsoleted API of vserver 1.3.x])
230 AH_TEMPLATE(VC_ENABLE_API_V13,      [Enable support for API of vserver 1.3.x])
231 AH_TEMPLATE(VC_ENABLE_API_NET,      [Enable support for network context API])
232 AH_TEMPLATE(VC_ENABLE_API_V21,      [Enable support for API of vserver 2.1.x])
233 AH_TEMPLATE(VC_ENABLE_API_V22,      [Enable support for API of vserver 2.2.x])
234 AH_TEMPLATE(VC_ENABLE_API_V23,      [Enable support for API of vserver 2.3.x])
235 AH_TEMPLATE(VC_ENABLE_API_NETV2,    [Enable support for new networking API])
236 AH_TEMPLATE(VC_ENABLE_API_OLDPROC,  [Enable API for a backward compatible /proc parsing])
237 AH_TEMPLATE(VC_ENABLE_API_OLDUTS,   [Enable API for a backward compatible uts handling])
238
239 AC_MSG_CHECKING([for supported APIs])
240 AC_ARG_ENABLE([apis],
241               [AC_HELP_STRING([--enable-apis=APIS],
242                               [enable support for the given apis; possible values are: legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2 ALL,NOLEGACY (default: v13,net,v21,v22,v23,netv2)])],
243               [],
244               [enable_apis=v13,net,v21,v22,v23,netv2])
245
246 test x"$enable_apis" != xALL      || enable_apis='legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2'
247 test x"$enable_apis" != xNOLEGACY || enable_apis='compat,v11,fscompat,v13,net,v21,v22,v23,netv2'
248 enable_api_oldproc=
249 enable_api_olduts=
250
251 echo $enable_apis | sed 's/,/\n/g' | while read i; do
252         case "$i" in
253                 (compat)        AC_DEFINE(VC_ENABLE_API_COMPAT,   1)
254                                 enable_api_oldproc=${enable_api_oldproc:-1}
255                                 enable_api_olduts=${enable_api_olduts:-1}
256                                 ;;
257                 (legacy)        AC_DEFINE(VC_ENABLE_API_LEGACY,   1)
258                                 enable_api_oldproc=${enable_api_oldproc:-1}
259                                 enable_api_olduts=${enable_api_olduts:-1}
260                                 ;;
261                 (v11)           AC_DEFINE(VC_ENABLE_API_V11,      1)
262                                 enable_api_oldproc=${enable_api_oldproc:-1}
263                                 enable_api_olduts=${enable_api_olduts:-1}
264                                 ;;
265                 (fscompat)      AC_DEFINE(VC_ENABLE_API_FSCOMPAT, 1);;
266                 (v13obs)        AC_DEFINE(VC_ENABLE_API_V13OBS,   1)
267                                 AC_DEFINE(VC_ENABLE_API_V13,      1);;
268                 (v13)           AC_DEFINE(VC_ENABLE_API_V13,      1);;
269                 (net)           AC_DEFINE(VC_ENABLE_API_NET,      1);;
270                 (v21)           AC_DEFINE(VC_ENABLE_API_V21,      1);;
271                 (v22)           AC_DEFINE(VC_ENABLE_API_V22,      1);;
272                 (v23)           AC_DEFINE(VC_ENABLE_API_V23,      1);;
273                 (netv2)         AC_DEFINE(VC_ENABLE_API_NETV2,    1);;
274                 (oldproc)       enable_api_oldproc=2;;
275                 (olduts)        enable_api_olduts=2;;
276                 (*)             AC_MSG_ERROR(['$i' is not a supported API]);;
277         esac
278 done
279 if test x"$enable_api_oldproc" != x; then
280         AC_DEFINE(VC_ENABLE_API_OLDPROC, 1)
281         test x"$enable_api_oldproc" != x2 && enable_apis="$enable_apis,oldproc"
282 fi
283 if test x"$enable_api_olduts" != x; then
284         AC_DEFINE(VC_ENABLE_API_OLDUTS, 1)
285         test x"$enable_api_olduts" != x2 && enable_apis="$enable_apis,olduts"
286 fi
287 AC_MSG_RESULT([$enable_apis])
288 dnl
289 dnl the check for used APIs ends here}
290 dnl
291 dnl ##########################
292
293
294 ENSC_CHECK_EXT2FS_HEADER
295 AC_CHECK_FUNCS([vserver])
296 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
297 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
298 AC_CHECK_TYPES(nid_t,,,[#include <sys/types.h>])
299 AC_CHECK_TYPES(tag_t,,,[#include <sys/types.h>])
300
301 AC_CHECK_HEADERS([sys/capability.h])
302
303 dnl vlogin might need -lutil
304 if test x"$ensc_have_dietlibc" = xno; then
305         AC_CHECK_FUNC([openpty],, [AC_CHECK_LIB([util], [openpty],, [AC_MSG_ERROR([
306 ****
307 **** openpty could not be found
308 ****])])])
309 fi
310
311
312 dnl ########################
313 dnl
314 dnl {crypto stuff
315 dnl
316 AC_ARG_WITH(crypto-api,
317             AC_HELP_STRING([--with-crypto-api=API],
318                            [select crypto api to be used; possible values are `none', `nss', `beecrypt', `auto' (default:auto)]),
319             [case $withval in
320                 (none|nss|beecrypt|auto)        ensc_crypto_api=$withval;;
321                 (yes)                           ensc_crypto_api=auto;;
322                 (no)                            ensc_crypto_api=none;;
323                 (*)     AC_MSG_ERROR([invalid crypto-api value, only none,nss,beecrypt,auto are supported]);;
324              esac],[ensc_crypto_api=auto])
325
326
327 dnl Now, check for matching crypto api. When selected 'auto', the
328 dnl first matching one wins
329
330 dnl ########################
331 dnl
332 dnl {check for beecrypt
333 dnl
334 case $ensc_crypto_api in
335 (auto|beecrypt)
336 if test x"$ensc_cv_c99_c99compiler" = xyes; then
337         ensc_have_beecrypt=yes
338
339         if test x"$ensc_have_beecrypt" = xyes; then
340                 AC_CHECK_HEADER([beecrypt/beecrypt.h], [ : ],
341                                 [ ensc_have_beecrypt=no ])
342         fi
343                         
344         if test x"$ensc_have_beecrypt" = xyes; then
345                 AC_CHECK_LIB(beecrypt, hashFunctionContextInit, [ : ],
346                              [ ensc_have_beecrypt=no ])
347         fi
348 else
349         ensc_have_beecrypt=no
350 fi;;
351 esac
352
353 case $ensc_crypto_api in
354 (auto)          if test x"$ensc_have_beecrypt"  = xyes; then
355                         AC_MSG_NOTICE([using beecrypt as crypto api])
356                         ensc_crypto_api=beecrypt
357                 fi;;
358 (beecrypt)      if test x"$ensc_have_beecrypt" != xyes; then
359                         AC_MSG_ERROR([beecrypt crypto api not found])
360                 fi;;
361 esac
362
363 AM_CONDITIONAL(ENSC_HAVE_BEECRYPT, test x"$ensc_have_beecrypt" = xyes)
364 AM_CONDITIONAL(ENSC_CAN_BEECRYPT_WITH_DIETLIBC, false)
365 dnl
366 dnl beecrypt stuff ends here}
367 dnl
368 dnl ########################
369
370
371 dnl ########################
372 dnl
373 dnl {check for nss
374 dnl
375
376 case $ensc_crypto_api in
377 (nss)   PKG_CHECK_MODULES(NSS, nss);;
378 (auto)  PKG_CHECK_MODULES(NSS, nss, [
379                 AC_MSG_NOTICE([using NSS as crypto api])
380                 ensc_crypto_api=nss]);;
381 esac
382
383 dnl
384 dnl nss stuff ends here}
385 dnl
386 dnl ########################
387
388 case $ensc_crypto_api in
389 (beecrypt)
390         ENSC_HAVE_CRYPTO=true
391         ENSC_CRYPTO_API=ENSC_CRYPTO_API_BEECRYPT
392         ENSC_CRYPTO_CFLAGS=
393         ENSC_CRYPTO_LIB=-lbeecrypt
394         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
395         ;;
396
397 (nss)
398         ENSC_HAVE_CRYPTO=true
399         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NSS
400         ENSC_CRYPTO_CFLAGS=$NSS_CFLAGS
401         ENSC_CRYPTO_LIB=$NSS_LIBS
402         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
403         ;;
404
405 (none|auto)
406         ENSC_HAVE_CRYPTO=false
407         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NONE
408         ENSC_CRYPTO_CFLAGS=
409         ENSC_CRYPTO_LIB=
410         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
411
412         AC_MSG_WARN([No crypto api found/select. This will disable the build of 'vhashify'])
413         ;;
414
415 (*)     AC_MSG_ERROR([internal error])
416 esac
417
418 AM_CONDITIONAL(ENSC_HAVE_CRYPTO, $ENSC_HAVE_CRYPTO)
419 AM_CONDITIONAL(ENSC_CAN_CRYPTO_WITH_DIETLIBC, $ENSC_CAN_CRYPTO_WITH_DIETLIBC)
420 AC_SUBST(ENSC_CRYPTO_CFLAGS, $ENSC_CRYPTO_CFLAGS)
421 AC_SUBST(ENSC_CRYPTO_LIB,    $ENSC_CRYPTO_LIB)
422 AC_DEFINE_UNQUOTED(ENSC_CRYPTO_API, $ENSC_CRYPTO_API, [Used crypto API])
423
424 dnl
425 dnl crypto stuff ends here}
426 dnl
427 dnl ########################
428
429
430 dnl Check what distro this is, use Gentoo initscripts if appropriate
431 AC_MSG_CHECKING([for host initscripts])
432 AC_ARG_WITH(initscripts, AC_HELP_STRING([--with-initscripts=TYPE], [force host initscripts; valid values are 'gentoo' and 'sysv' (default: guess)]), [
433         case "$withval" in
434         gentoo) ensc_with_init=gentoo;;
435         sysv)   ensc_with_init=sysv;;
436         *)      AC_MSG_ERROR([invalid initscripts value, only gentoo and sysv are supported]);;
437         esac
438         ], [
439         if test -e /etc/gentoo-release; then
440                 ensc_with_init=gentoo
441         else
442                 ensc_with_init=sysv
443         fi
444         ])
445 AC_MSG_RESULT([$ensc_with_init])
446 AM_CONDITIONAL(HAVE_GENTOO_INIT, test x"$ensc_with_init" = xgentoo)
447 AM_CONDITIONAL(HAVE_SYSV_INIT, test x"$ensc_with_init" = xsysv)
448
449
450 dnl ########################
451 dnl Check for Python
452
453 ensc_have_python=yes
454 AM_PATH_PYTHON([2.4],, [:])
455 if test "x$PYTHON" = x:; then
456         ensc_have_python=no
457 fi
458 if test x$ensc_have_python = xyes; then
459         PYTHON_CFLAGS=-I`$PYTHON -c 'from distutils.sysconfig import get_python_inc; print get_python_inc(1)'`
460         PYTHON_LDFLAGS=-L`$PYTHON -c 'from distutils.sysconfig import get_python_lib; print get_python_lib(1)'`
461         AC_SUBST(PYTHON_CFLAGS)
462         AC_SUBST(PYTHON_LDFLAGS)
463 else
464         ensc_have_python=no
465 fi
466 AC_PATH_PROG([CTAGS], [ctags], [no])
467 if test "x$CTAGS" = xno; then
468         ensc_have_python=no
469 fi
470 AM_CONDITIONAL([HAVE_PYTHON], [test x$ensc_have_python = xyes])
471
472 dnl Python stuff ends here
473 dnl ########################
474
475
476 dnl ########################
477 dnl Library versioning
478
479 ensc_have_versioning=yes
480 AC_ARG_ENABLE(versioning, AC_HELP_STRING([--disable-versioning], [Disable library versioning]), [ensc_have_versioning="$enableval"])
481 AM_CONDITIONAL([HAVE_VERSIONING], [test "x$ensc_have_versioning" = xyes])
482 if test "x$ensc_have_versioning" = xyes; then
483         AC_DEFINE([HAVE_VERSIONING], [1], [Define this to use library versioning])
484 fi
485
486 dnl /Library versioning
487 dnl ########################
488
489
490 dnl BIG HACK! Do some autodetection here!
491 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
492
493 if false; then
494         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
495 fi
496
497 AC_DEFINE(_FILE_OFFSET_BITS, [64], [Use 64bit interface for filesystem operations])
498
499 dnl ########################
500 dnl
501 dnl {The final info-page
502 dnl
503 ensc_cxx_affected=" (affected: vbuild, vcheck)"
504 ensc_c99_affected=" (affected: vunify, vcopy, vhashify, vdlimit)"
505 ensc_diet_msg=" (you have been warned)"
506 ensc_diet_version_msg=" ($ensc_version_dietlibc)"
507 ensc_diet_compat_msg=" (using -lcompat)"
508 test x"$ensc_cv_cxx_cxxcompiler"    = xno || ensc_cxx_affected=
509 test x"$ensc_cv_c99_c99compiler"    = xno || ensc_c99_affected=
510 test x"$ensc_have_dietlibc"         = xno || ensc_diet_msg=
511 test x"$ensc_version_dietlibc"     != x   || ensc_diet_version_msg=
512 test x"$ensc_have_dietlibc$ensc_cv_c_dietlibc_compat" = xyesyes || ensc_diet_compat_msg=
513
514 AH_BOTTOM([#include "compat.h"
515 ])
516 AC_CONFIG_COMMANDS_PRE([
517                         FEATURES_TXT="\
518 Features:
519                        CC: $CC, $($CC   --version | sed -e '1p;d')
520                       CXX: $CXX, $($CXX --version | sed -e '1p;d')
521                  CPPFLAGS: '$CPPFLAGS'
522                    CFLAGS: '$CFLAGS'
523                  CXXFLAGS: '$CXXFLAGS'
524                build/host: $build/$host
525              Use dietlibc: $ensc_have_dietlibc$ensc_diet_version_msg$ensc_diet_msg$ensc_diet_compat_msg
526        Build C++ programs: $ensc_cv_cxx_cxxcompiler$ensc_cxx_affected
527        Build C99 programs: $ensc_cv_c99_c99compiler$ensc_c99_affected
528            Available APIs: $enable_apis
529             ext2fs Source: $ensc_cv_test_ext2fs_header
530     syscall(2) invocation: $with_syscall
531       vserver(2) syscall#: $ensc_cv_value_syscall_vserver
532                crypto api: $ensc_crypto_api
533           python bindings: $ensc_have_python
534    use library versioning: $ensc_have_versioning
535    
536 Paths:
537                    prefix: $prefix
538         sysconf-Directory: $sysconfdir
539             cfg-Directory: $sysconfdir/vservers
540          initrd-Directory: $initrddir
541        pkgstate-Directory: $localstatedir/run/vservers
542           vserver-Rootdir: $vserverdir
543 "
544                         echo "$FEATURES_TXT" >FEATURES.txt
545                         ])
546 dnl
547 dnl final info-page ends here}
548 dnl
549 dnl ########################
550
551 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile lib/apidoc/Doxyfile])
552 AC_OUTPUT
553
554 AC_MSG_NOTICE([
555
556 $PACKAGE_STRING
557
558 $FEATURES_TXT])