gentoo: use /var/run for new /run compatibility
[util-vserver.git] / configure.ac
1 dnl $Id$
2
3 dnl Copyright (C) 2003,2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
4 dnl
5 dnl This program is free software; you can redistribute it and/or modify
6 dnl it under the terms of the GNU General Public License as published by
7 dnl the Free Software Foundation; either version 2, or (at your option)
8 dnl any later version.
9 dnl
10 dnl This program is distributed in the hope that it will be useful,
11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 dnl GNU General Public License for more details.
14 dnl
15 dnl You should have received a copy of the GNU General Public License
16 dnl along with this program; if not, write to the Free Software
17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18 dnl
19 dnl
20 dnl As a special exception to the GNU General Public License, if you
21 dnl distribute this file as part of a program that contains a configuration
22 dnl script generated by Autoconf, you may include it under the same
23 dnl distribution terms that you use for the rest of that program.
24 dnl
25
26 AC_PREREQ(2.57)
27 AC_INIT(util-vserver, 0.30.215, vserver@list.linux-vserver.org)
28 AC_CONFIG_SRCDIR([src/capchroot.c])
29 AC_CONFIG_HEADER([config.h])
30 AC_CONFIG_MACRO_DIR([m4])
31
32 AM_INIT_AUTOMAKE([1.9 gnits dist-bzip2 subdir-objects])
33 AM_MAINTAINER_MODE
34
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37
38 AC_SUBST(GPG_KEY, "0xFFD316AC53ACA43A!")
39
40 # Checks for programs.
41 AC_PROG_CC
42 AC_PROG_INSTALL
43 AC_PROG_LN_S
44 AM_PROG_CC_C_O
45 PKG_PROG_PKG_CONFIG
46 ENSC_C99COMPILER
47 AM_PROG_MKDIR_P
48
49 ENSC_SET_SEARCHPATH([$PATH:/sbin:/usr/sbin:/usr/local/sbin])
50 ENSC_PATHPROG_STANDARD_TOOLS
51
52 ENSC_PATHPROG(IP,        ip,,      [Usually, this tool is shipped in the 'iproute' or 'iproute2' package of your distribution])
53 ENSC_PATHPROG(IPTABLES,  iptables)
54 ENSC_PATHPROG(MODPROBE,  modprobe)
55 ENSC_PATHPROG(NAMEIF,    nameif)
56 ENSC_PATHPROG(NOHUP,     nohup)
57 ENSC_PATHPROG(RMMOD,     rmmod)
58 ENSC_PATHPROG(VCONFIG,   vconfig,, [See http://www.candelatech.com/~greear/vlan.html; usually this tool is shipped in the 'vconfig' or 'vlan' package of your distribution])
59 ENSC_PATHPROG(WGET,      wget)
60 ENSC_PATHPROG(IONICE,    ionice,  [],  [This is usually shipped in the 'util-linux(-ng)' or 'schedutils' package])
61 ENSC_PATHPROG(FILE,      file,    [file])
62 ENSC_PATHPROG(GZIP,      gzip,    [gzip])
63 ENSC_PATHPROG(BZIP2,     bzip2,   [bzip2])
64 ENSC_PATHPROG(CPIO,      cpio,    [cpio])
65 ENSC_PATHPROG(RESTORE,   restore, [restore])
66 ENSC_PATHPROG(RSYNC,     rsync,   [rsync])
67 ENSC_PATHPROG(STRACE,    strace,  [strace])
68 ENSC_PATHPROG(FSCK,      fsck)
69 ENSC_PATHPROG(FIND,      find)
70
71 ENSC_PATHPROG(DOXYGEN,   doxygen,  [:])
72 ENSC_PATHPROG(XSLTP,     xsltp,    [:])
73 ENSC_PATHPROG(XSLTPROC,  xsltproc, [:])
74
75
76 AM_CONDITIONAL(HAVE_XSLTP,    test "$XSLTP"    != ':')
77 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != ':')
78
79 if test x"$prefix" = x/; then
80         prefix=
81 fi
82
83 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
84
85 AC_MSG_CHECKING([whether to enable extra optimizations])
86 AC_ARG_ENABLE([extra-optimizations],
87               [AC_HELP_STRING([--disable-extra-optimizations],
88                               [disable certain extra optimizations (default: no)])],
89               [case "$enableval" in
90                   (yes) use_extra_optimizations=1;;
91                   (no)  use_extra_optimizations=;;
92                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--disable-extra-optimizations']);;
93                esac],
94               [use_extra_optimizations=1])
95
96 if test x"$use_extra_optimizations" = x; then
97         AC_MSG_RESULT(no)
98 else
99         AC_MSG_RESULT(yes)
100         ENSC_CHECK_CC_FLAG([-funit-at-a-time])
101 fi
102
103 AC_MSG_CHECKING([whether to enable debug-code in library])
104 AC_ARG_ENABLE([lib-debug],
105               [AC_HELP_STRING([--enable-lib-debug],
106                               [enable additional debug code in library (default: no)])],
107               [case "$enableval" in
108                   (yes) use_lib_debug=1;;
109                   (no)  use_lib_debug=;;
110                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
111                esac],
112               [ use_lib_debug= ])
113
114 if test x"$use_lib_debug" = x; then
115         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
116         AC_MSG_RESULT(no)
117 else
118         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
119         AC_MSG_RESULT(yes)
120 fi
121
122 AC_MSG_CHECKING([whether to enable expensive tests])
123 AC_ARG_ENABLE([expensive-tests],
124               [AC_HELP_STRING([--enable-expensive-tests],
125                               [disable tests which might be expensive on some systems (default: no)])],
126               [case "$enableval" in
127                  (yes|no)  use_expensive_tests=$enableval;;
128                  (*)       AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-expensive-tests']);;
129                esac],
130               [ use_expensive_tests=no ])
131 AC_MSG_RESULT($use_expensive_tests)
132
133 AC_SUBST(ENSC_USE_EXPENSIVE_TESTS, "$use_expensive_tests")
134
135
136 ENSC_CHECK_PERSONALITY_FLAGS
137
138 AC_ARG_VAR(CC, [The C compiler])
139
140 ENSC_INITRDDIR(initrddir)
141 ENSC_RELEASE(RELEASE_CPPFLAGS)
142
143 # HACK: This needs to be before ENSC_DIETLIBC_NEED_COMPAT, or the alternative
144 # syscalls will never be enabled for glibc.
145 ENSC_SYSCALLNR(vserver,273,[lib/syscall-fallback.h])
146 ENSC_SYSCALL
147
148 dnl ###########################
149 dnl
150 dnl {some dietlibc related tests
151 dnl
152
153 case $host_cpu in
154         (i*86|athlon)   min_diet_ver=0.25;;
155         (ia64|hppa*)    min_diet_ver=0.29;;
156         (sparc*)        min_diet_ver=0.30;;
157         (x86_64)        min_diet_ver=0.27;;
158         (*)             min_diet_ver=0.28;;
159 esac
160
161 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC, [$min_diet_ver])
162
163 if test x"$ensc_have_dietlibc" = xno; then
164         AC_MSG_WARN([***                                                         ***])
165         AC_MSG_WARN([*** it is strongly recommended to link util-vserver against ***])
166         AC_MSG_WARN([*** dietlibc;  glibc's NSS functions are very unreliable in ***])
167         AC_MSG_WARN([*** chroot() environments,  so you have to  expect problems ***])
168         AC_MSG_WARN([*** there.                                                  ***])
169         AC_MSG_WARN([***                                                         ***])
170         AM_CONDITIONAL(USE_DIETLIBC_COMPAT, false)
171 else
172         # HACK: libtool does not have cmdline options to build only
173         # dynamic libraries; this can be done with the
174         # '--disable-static' ./configure option only.  As our static
175         # libraries will be build with dietlibc, we have to do set
176         # this option which is evaluated by 'AC_PROG_LIBTOOL'
177         # below.  Therefore, this macro must not be called earlier.
178         enable_static=no
179
180         ENSC_DIETLIBC_NEED_COMPAT(USE_DIETLIBC_COMPAT)
181 fi
182
183 AM_CONDITIONAL(ENSC_USE_DIETLIBC, test x"$ensc_have_dietlibc" = xyes)
184 AM_CONDITIONAL(ENSC_USE_GLIBC,    true)
185
186 # HACK: see comments at 'enable_static' above
187 AC_PROG_LIBTOOL
188 dnl
189 dnl dietlibc stuff ends here}
190 dnl
191 dnl ##########################
192
193
194 ENSC_UV_VROOTDIR(vserverdir)
195 ENSC_CHANGELOG
196
197
198 dnl ##########################
199 dnl
200 dnl {Check whether to use external kernel headers
201 dnl
202 AC_MSG_CHECKING([whether to use internal kernel headers])
203 AC_ARG_ENABLE([internal-headers],
204               [AC_HELP_STRING([--disable-internal-headers],
205                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
206               [case "$enableval" in
207                   (yes|no) ;;
208                   (*)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
209                esac],
210               [enable_internal_headers=yes])
211
212 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
213 AC_MSG_RESULT([$enable_internal_headers])
214 dnl
215 dnl the check regarding external kernel headers ends here}
216 dnl
217 dnl ##########################
218
219 dnl ##########################
220 dnl
221 dnl {Check for the APIs to be used
222 dnl
223 AH_TEMPLATE(VC_ENABLE_API_COMPAT,   [Enable support for compatibility syscall API])
224 AH_TEMPLATE(VC_ENABLE_API_LEGACY,   [Enable support for old, /proc parsing API])
225 AH_TEMPLATE(VC_ENABLE_API_V11,      [Enable support for API of vserver 1.1.x])
226 AH_TEMPLATE(VC_ENABLE_API_FSCOMPAT, [Enable support for filesystem compatibility API])
227 AH_TEMPLATE(VC_ENABLE_API_V13OBS,   [Enable support for some obsoleted API of vserver 1.3.x])
228 AH_TEMPLATE(VC_ENABLE_API_V13,      [Enable support for API of vserver 1.3.x])
229 AH_TEMPLATE(VC_ENABLE_API_NET,      [Enable support for network context API])
230 AH_TEMPLATE(VC_ENABLE_API_V21,      [Enable support for API of vserver 2.1.x])
231 AH_TEMPLATE(VC_ENABLE_API_V22,      [Enable support for API of vserver 2.2.x])
232 AH_TEMPLATE(VC_ENABLE_API_V23,      [Enable support for API of vserver 2.3.x])
233 AH_TEMPLATE(VC_ENABLE_API_NETV2,    [Enable support for new networking API])
234 AH_TEMPLATE(VC_ENABLE_API_OLDPROC,  [Enable API for a backward compatible /proc parsing])
235 AH_TEMPLATE(VC_ENABLE_API_OLDUTS,   [Enable API for a backward compatible uts handling])
236
237 AC_MSG_CHECKING([for supported APIs])
238 AC_ARG_ENABLE([apis],
239               [AC_HELP_STRING([--enable-apis=APIS],
240                               [enable support for the given apis; possible values are: legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2 ALL,NOLEGACY (default: v13,net,v21,v22,v23,netv2)])],
241               [],
242               [enable_apis=v13,net,v21,v22,v23,netv2])
243
244 test x"$enable_apis" != xALL      || enable_apis='legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2'
245 test x"$enable_apis" != xNOLEGACY || enable_apis='compat,v11,fscompat,v13,net,v21,v22,v23,netv2'
246 enable_api_oldproc=
247 enable_api_olduts=
248
249 echo $enable_apis | sed 's/,/\n/g' | while read i; do
250         case "$i" in
251                 (compat)        AC_DEFINE(VC_ENABLE_API_COMPAT,   1)
252                                 enable_api_oldproc=${enable_api_oldproc:-1}
253                                 enable_api_olduts=${enable_api_olduts:-1}
254                                 ;;
255                 (legacy)        AC_DEFINE(VC_ENABLE_API_LEGACY,   1)
256                                 enable_api_oldproc=${enable_api_oldproc:-1}
257                                 enable_api_olduts=${enable_api_olduts:-1}
258                                 ;;
259                 (v11)           AC_DEFINE(VC_ENABLE_API_V11,      1)
260                                 enable_api_oldproc=${enable_api_oldproc:-1}
261                                 enable_api_olduts=${enable_api_olduts:-1}
262                                 ;;
263                 (fscompat)      AC_DEFINE(VC_ENABLE_API_FSCOMPAT, 1);;
264                 (v13obs)        AC_DEFINE(VC_ENABLE_API_V13OBS,   1)
265                                 AC_DEFINE(VC_ENABLE_API_V13,      1);;
266                 (v13)           AC_DEFINE(VC_ENABLE_API_V13,      1);;
267                 (net)           AC_DEFINE(VC_ENABLE_API_NET,      1);;
268                 (v21)           AC_DEFINE(VC_ENABLE_API_V21,      1);;
269                 (v22)           AC_DEFINE(VC_ENABLE_API_V22,      1);;
270                 (v23)           AC_DEFINE(VC_ENABLE_API_V23,      1);;
271                 (netv2)         AC_DEFINE(VC_ENABLE_API_NETV2,    1);;
272                 (oldproc)       enable_api_oldproc=2;;
273                 (olduts)        enable_api_olduts=2;;
274                 (*)             AC_MSG_ERROR(['$i' is not a supported API]);;
275         esac
276 done
277 if test x"$enable_api_oldproc" != x; then
278         AC_DEFINE(VC_ENABLE_API_OLDPROC, 1)
279         test x"$enable_api_oldproc" != x2 && enable_apis="$enable_apis,oldproc"
280 fi
281 if test x"$enable_api_olduts" != x; then
282         AC_DEFINE(VC_ENABLE_API_OLDUTS, 1)
283         test x"$enable_api_olduts" != x2 && enable_apis="$enable_apis,olduts"
284 fi
285 AC_MSG_RESULT([$enable_apis])
286 dnl
287 dnl the check for used APIs ends here}
288 dnl
289 dnl ##########################
290
291
292 ENSC_CHECK_EXT2FS_HEADER
293 AC_CHECK_FUNCS([vserver])
294 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
295 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
296 AC_CHECK_TYPES(nid_t,,,[#include <sys/types.h>])
297 AC_CHECK_TYPES(tag_t,,,[#include <sys/types.h>])
298
299 AC_CHECK_HEADERS([sys/capability.h])
300
301 dnl vlogin might need -lutil
302 if test x"$ensc_have_dietlibc" = xno; then
303         AC_CHECK_FUNC([openpty],, [AC_CHECK_LIB([util], [openpty],, [AC_MSG_ERROR([
304 ****
305 **** openpty could not be found
306 ****])])])
307 fi
308
309
310 dnl ########################
311 dnl
312 dnl {crypto stuff
313 dnl
314 AC_ARG_WITH(crypto-api,
315             AC_HELP_STRING([--with-crypto-api=API],
316                            [select crypto api to be used; possible values are `none', `nss', `beecrypt', `auto' (default:auto)]),
317             [case $withval in
318                 (none|nss|beecrypt|auto)        ensc_crypto_api=$withval;;
319                 (yes)                           ensc_crypto_api=auto;;
320                 (no)                            ensc_crypto_api=none;;
321                 (*)     AC_MSG_ERROR([invalid crypto-api value, only none,nss,beecrypt,auto are supported]);;
322              esac],[ensc_crypto_api=auto])
323
324
325 dnl Now, check for matching crypto api. When selected 'auto', the
326 dnl first matching one wins
327
328 dnl ########################
329 dnl
330 dnl {check for beecrypt
331 dnl
332 case $ensc_crypto_api in
333 (auto|beecrypt)
334 if test x"$ensc_cv_c99_c99compiler" = xyes; then
335         ensc_have_beecrypt=yes
336
337         if test x"$ensc_have_beecrypt" = xyes; then
338                 AC_CHECK_HEADER([beecrypt/beecrypt.h], [ : ],
339                                 [ ensc_have_beecrypt=no ])
340         fi
341
342         if test x"$ensc_have_beecrypt" = xyes; then
343                 AC_CHECK_LIB(beecrypt, hashFunctionContextInit, [ : ],
344                              [ ensc_have_beecrypt=no ])
345         fi
346 else
347         ensc_have_beecrypt=no
348 fi;;
349 esac
350
351 case $ensc_crypto_api in
352 (auto)          if test x"$ensc_have_beecrypt"  = xyes; then
353                         AC_MSG_NOTICE([using beecrypt as crypto api])
354                         ensc_crypto_api=beecrypt
355                 fi;;
356 (beecrypt)      if test x"$ensc_have_beecrypt" != xyes; then
357                         AC_MSG_ERROR([beecrypt crypto api not found])
358                 fi;;
359 esac
360
361 AM_CONDITIONAL(ENSC_HAVE_BEECRYPT, test x"$ensc_have_beecrypt" = xyes)
362 AM_CONDITIONAL(ENSC_CAN_BEECRYPT_WITH_DIETLIBC, false)
363 dnl
364 dnl beecrypt stuff ends here}
365 dnl
366 dnl ########################
367
368
369 dnl ########################
370 dnl
371 dnl {check for nss
372 dnl
373
374 case $ensc_crypto_api in
375 (nss)   PKG_CHECK_MODULES(NSS, nss);;
376 (auto)  PKG_CHECK_MODULES(NSS, nss, [
377                 AC_MSG_NOTICE([using NSS as crypto api])
378                 ensc_crypto_api=nss]);;
379 esac
380
381 dnl
382 dnl nss stuff ends here}
383 dnl
384 dnl ########################
385
386 case $ensc_crypto_api in
387 (beecrypt)
388         ENSC_HAVE_CRYPTO=true
389         ENSC_CRYPTO_API=ENSC_CRYPTO_API_BEECRYPT
390         ENSC_CRYPTO_CFLAGS=
391         ENSC_CRYPTO_LIB=-lbeecrypt
392         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
393         ;;
394
395 (nss)
396         ENSC_HAVE_CRYPTO=true
397         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NSS
398         ENSC_CRYPTO_CFLAGS=$NSS_CFLAGS
399         ENSC_CRYPTO_LIB=$NSS_LIBS
400         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
401         ;;
402
403 (none|auto)
404         ENSC_HAVE_CRYPTO=false
405         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NONE
406         ENSC_CRYPTO_CFLAGS=
407         ENSC_CRYPTO_LIB=
408         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
409
410         AC_MSG_WARN([No crypto api found/select. This will disable the build of 'vhashify'])
411         ;;
412
413 (*)     AC_MSG_ERROR([internal error])
414 esac
415
416 AM_CONDITIONAL(ENSC_HAVE_CRYPTO, $ENSC_HAVE_CRYPTO)
417 AM_CONDITIONAL(ENSC_CAN_CRYPTO_WITH_DIETLIBC, $ENSC_CAN_CRYPTO_WITH_DIETLIBC)
418 AC_SUBST(ENSC_CRYPTO_CFLAGS, $ENSC_CRYPTO_CFLAGS)
419 AC_SUBST(ENSC_CRYPTO_LIB,    $ENSC_CRYPTO_LIB)
420 AC_DEFINE_UNQUOTED(ENSC_CRYPTO_API, $ENSC_CRYPTO_API, [Used crypto API])
421
422 dnl
423 dnl crypto stuff ends here}
424 dnl
425 dnl ########################
426
427
428 dnl Check what distro this is, use Gentoo initscripts if appropriate
429 AC_MSG_CHECKING([for host initscripts])
430 AC_ARG_WITH(initscripts, AC_HELP_STRING([--with-initscripts=TYPE], [force host initscripts; valid values are 'gentoo' and 'sysv' (default: guess)]), [
431         case "$withval" in
432         gentoo) ensc_with_init=gentoo;;
433         sysv)   ensc_with_init=sysv;;
434         *)      AC_MSG_ERROR([invalid initscripts value, only gentoo and sysv are supported]);;
435         esac
436         ], [
437         if test -e /etc/gentoo-release; then
438                 ensc_with_init=gentoo
439         else
440                 ensc_with_init=sysv
441         fi
442         ])
443 AC_MSG_RESULT([$ensc_with_init])
444 AM_CONDITIONAL(HAVE_GENTOO_INIT, test x"$ensc_with_init" = xgentoo)
445 AM_CONDITIONAL(HAVE_SYSV_INIT, test x"$ensc_with_init" = xsysv)
446
447
448 dnl ########################
449 dnl Check for Python
450
451 ensc_have_python=yes
452 AM_PATH_PYTHON([2.4],, [:])
453 if test "x$PYTHON" = x:; then
454         ensc_have_python=no
455 fi
456 if test x$ensc_have_python = xyes; then
457         PYTHON_CFLAGS=-I`$PYTHON -c 'from distutils.sysconfig import get_python_inc; print(get_python_inc(1))'`
458         PYTHON_LDFLAGS=-L`$PYTHON -c 'from distutils.sysconfig import get_python_lib; print(get_python_lib(1))'`
459         AC_SUBST(PYTHON_CFLAGS)
460         AC_SUBST(PYTHON_LDFLAGS)
461 else
462         ensc_have_python=no
463 fi
464 AC_PATH_PROG([CTAGS], [ctags], [no])
465 if test "x$CTAGS" = xno; then
466         ensc_have_python=no
467 fi
468 AM_CONDITIONAL([HAVE_PYTHON], [test x$ensc_have_python = xyes])
469
470 dnl Python stuff ends here
471 dnl ########################
472
473
474 dnl ########################
475 dnl Library versioning
476
477 ensc_have_versioning=yes
478 AC_ARG_ENABLE(versioning, AC_HELP_STRING([--disable-versioning], [Disable library versioning]), [ensc_have_versioning="$enableval"])
479 AM_CONDITIONAL([HAVE_VERSIONING], [test "x$ensc_have_versioning" = xyes])
480 if test "x$ensc_have_versioning" = xyes; then
481         AC_DEFINE([HAVE_VERSIONING], [1], [Define this to use library versioning])
482 fi
483
484 dnl /Library versioning
485 dnl ########################
486
487
488 dnl BIG HACK! Do some autodetection here!
489 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
490
491 if false; then
492         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
493 fi
494
495 AC_DEFINE(_FILE_OFFSET_BITS, [64], [Use 64bit interface for filesystem operations])
496
497 dnl ########################
498 dnl
499 dnl {The final info-page
500 dnl
501 ensc_cxx_affected=" (affected: vbuild, vcheck)"
502 ensc_c99_affected=" (affected: vunify, vcopy, vhashify, vdlimit)"
503 ensc_diet_msg=" (you have been warned)"
504 ensc_diet_version_msg=" ($ensc_version_dietlibc)"
505 ensc_diet_compat_msg=" (using -lcompat)"
506 test x"$ensc_cv_cxx_cxxcompiler"    = xno || ensc_cxx_affected=
507 test x"$ensc_cv_c99_c99compiler"    = xno || ensc_c99_affected=
508 test x"$ensc_have_dietlibc"         = xno || ensc_diet_msg=
509 test x"$ensc_version_dietlibc"     != x   || ensc_diet_version_msg=
510 test x"$ensc_have_dietlibc$ensc_cv_c_dietlibc_compat" = xyesyes || ensc_diet_compat_msg=
511
512 AH_BOTTOM([#include "compat.h"
513 ])
514 AC_CONFIG_COMMANDS_PRE([
515                         FEATURES_TXT="\
516 Features:
517                        CC: $CC, $($CC   --version | sed -e '1p;d')
518                  CPPFLAGS: '$CPPFLAGS'
519                    CFLAGS: '$CFLAGS'
520                build/host: $build/$host
521              Use dietlibc: $ensc_have_dietlibc$ensc_diet_version_msg$ensc_diet_msg$ensc_diet_compat_msg
522        Build C++ programs: $ensc_cv_cxx_cxxcompiler$ensc_cxx_affected
523        Build C99 programs: $ensc_cv_c99_c99compiler$ensc_c99_affected
524            Available APIs: $enable_apis
525             ext2fs Source: $ensc_cv_test_ext2fs_header
526     syscall(2) invocation: $with_syscall
527       vserver(2) syscall#: $ensc_cv_value_syscall_vserver
528                crypto api: $ensc_crypto_api
529           python bindings: $ensc_have_python
530    use library versioning: $ensc_have_versioning
531
532 Paths:
533                    prefix: $prefix
534         sysconf-Directory: $sysconfdir
535             cfg-Directory: $sysconfdir/vservers
536          initrd-Directory: $initrddir
537        pkgstate-Directory: $localstatedir/run/vservers
538           vserver-Rootdir: $vserverdir
539 "
540                         echo "$FEATURES_TXT" >FEATURES.txt
541                         ])
542 dnl
543 dnl final info-page ends here}
544 dnl
545 dnl ########################
546
547 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile lib/apidoc/Doxyfile])
548 AC_OUTPUT
549
550 AC_MSG_NOTICE([
551
552 $PACKAGE_STRING
553
554 $FEATURES_TXT])