use a more modern version which accepts 'DIET' and 'DIETFLAGS' as
[util-vserver.git] / util-vserver / m4 / ensc_dietlibc.m4
1 dnl $Id$
2
3 dnl Copyright (C) 2002 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
4 dnl  
5 dnl This program is free software; you can redistribute it and/or modify
6 dnl it under the terms of the GNU General Public License as published by
7 dnl the Free Software Foundation; version 2 of the License.
8 dnl  
9 dnl This program is distributed in the hope that it will be useful,
10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12 dnl GNU General Public License for more details.
13 dnl  
14 dnl You should have received a copy of the GNU General Public License
15 dnl along with this program; if not, write to the Free Software
16 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
17
18 AC_DEFUN([_ENSC_DIETLIBC_C99],
19 [
20         AH_TEMPLATE([ENSC_DIETLIBC_C99], [Define to 1 if dietlibc supports C99])
21
22         AC_CACHE_CHECK([whether dietlibc supports C99], [ensc_cv_c_dietlibc_c99],
23         [
24                 _ensc_dietlibc_c99_old_CFLAGS=$CFLAGS
25                 _ensc_dietlibc_c99_old_CC=$CC
26
27                 CFLAGS="-std=c99"
28                 CC="${DIET:-diet} $CC"
29
30                 AC_LANG_PUSH(C)
31                 AC_COMPILE_IFELSE([/* */],[
32                         AC_COMPILE_IFELSE([
33                                 #include <stdint.h>
34                                 #include <sys/cdefs.h>
35                                 #if defined(inline)
36                                 #  error 'inline' badly defined
37                                 #endif
38                                 volatile uint64_t       a;
39                         ],
40                         [ensc_cv_c_dietlibc_c99=yes],
41                         [ensc_cv_c_dietlibc_c99=no])],
42                         [ensc_cv_c_dietlibc_c99='skipped (compiler does not support C99)'])
43                 AC_LANG_POP
44
45                 CC=$_ensc_dietlibc_c99_old_CC
46                 CFLAGS=$_ensc_dietlibc_c99_old_CFLAGS
47         ])
48
49         if test x"$ensc_cv_c_dietlibc_c99" = xyes; then
50                 AC_DEFINE(ENSC_DIETLIBC_C99,1)
51         fi
52 ])
53
54 dnl Usage: ENSC_ENABLE_DIETLIBC(<conditional>[,<min-version>])
55 dnl        <conditional> ... automake-conditional which will be set when
56 dnl                          dietlibc shall be enabled
57 dnl        provides:
58 dnl        * $ENSC_VERSION_DIETLIBC_NUM and
59 dnl        * $ENSC_VERSION_DIETLIBC
60
61 AC_DEFUN([ENSC_ENABLE_DIETLIBC],
62 [
63         AC_MSG_CHECKING([whether to enable dietlibc])
64
65         AC_ARG_VAR(DIET,      [The 'diet' wrapper (default: diet)])
66         AC_ARG_VAR(DIETFLAGS, [Flags passed to the 'diet' wrapper (default: -O)])
67
68         : ${DIET:=diet}
69         : ${DIETFLAGS=-Os}
70
71         AC_ARG_ENABLE([dietlibc],
72                       [AC_HELP_STRING([--disable-dietlibc],
73                                       [do not use dietlibc (default: use dietlibc)])],
74                       [case "$enableval" in
75                           (yes) use_dietlibc=forced;;
76                           (no)  use_dietlibc=forced_no;;
77                           (*)   AC_MSG_ERROR(['$enableval' is not a valid value for --enable-dietlibc]);;
78                        esac],
79                       [which "$DIET" >/dev/null 2>/dev/null && use_dietlibc=detected || use_dietlibc=detected_no])
80
81         if test "$use_dietlibc" = detected -a '$2'; then
82             _dietlibc_ver=$($DIET -v 2>&1 | sed '1p;d')
83             _dietlibc_ver=${_dietlibc_ver##*diet version }
84             _dietlibc_ver=${_dietlibc_ver##*dietlibc-}
85             _dietlibc_ver_maj=${_dietlibc_ver%%.*}
86             _dietlibc_ver_min=${_dietlibc_ver##*.}
87             _dietlibc_ver_min=${_dietlibc_ver_min%%[[!0-9]]*}
88             _dietlibc_cmp=$2
89             _dietlibc_cmp_maj=${_dietlibc_cmp%%.*}
90             _dietlibc_cmp_min=${_dietlibc_cmp##*.}
91
92             ENSC_VERSION_DIETLIBC=$_dietlibc_ver_maj.$_dietlibc_ver_min
93
94             let _dietlibc_ver=_dietlibc_ver_maj*1000+_dietlibc_ver_min 2>/dev/null || _dietlibc_ver=0
95             let _dietlibc_cmp=_dietlibc_cmp_maj*1000+_dietlibc_cmp_min
96
97             test $_dietlibc_ver -ge $_dietlibc_cmp || use_dietlibc=detected_old
98         else
99             ENSC_VERSION_DIETLIBC=
100             _dietlibc_ver=-1
101         fi
102
103         ENSC_VERSION_DIETLIBC_NUM=$_dietlibc_ver
104         ensc_have_dietlibc=no
105
106         case x"$use_dietlibc" in
107             xdetected)
108                 AM_CONDITIONAL($1, true)
109                 AC_MSG_RESULT([yes (autodetected, $ENSC_VERSION_DIETLIBC)])
110                 ensc_have_dietlibc=yes
111                 ;;
112             xforced)
113                 AM_CONDITIONAL($1, true)
114                 AC_MSG_RESULT([yes (forced)])
115                 ensc_have_dietlibc=yes
116                 ;;
117             xdetected_no)
118                 AM_CONDITIONAL($1, false)
119                 AC_MSG_RESULT([no (detected)])
120                 ;;
121             xdetected_old)
122                 AM_CONDITIONAL($1, false)
123                 AC_MSG_RESULT([no (too old; $2+ required, $ENSC_VERSION_DIETLIBC found)])
124                 ;;
125             xforced_no)
126                 AM_CONDITIONAL($1, false)
127                 AC_MSG_RESULT([no (forced)])
128                 ;;
129             *)
130                 AC_MSG_ERROR([internal error, use_dietlibc was "$use_dietlibc"])
131                 ;;
132         esac
133
134         if test x"$ensc_have_dietlibc" != xno; then
135                 _ENSC_DIETLIBC_C99
136         fi
137 ])
138
139
140 dnl Usage: ENSC_DIETLIBC_SANITYCHECK
141 AC_DEFUN([ENSC_DIETLIBC_SANITYCHECK],
142 [
143         AC_REQUIRE([AC_CANONICAL_HOST])
144         AC_REQUIRE([ENSC_ENABLE_DIETLIBC])
145
146         if test "$host_cpu" = x86_64 -a $ENSC_VERSION_DIETLIBC_NUM -le 0027; then
147                 AC_MSG_WARN([***                                                             ***])
148                 AC_MSG_WARN([*** dietlibc<=0.27 is known to be broken for x86_64 systems     ***])
149                 AC_MSG_WARN([*** please make sure that at least the environ.S fix is applied ***])
150                 AC_MSG_WARN([*** and lib/__nice.c added                                      ***])
151                 AC_MSG_WARN([***                                                             ***])
152         fi
153 ])