util-vserver/configure.ac

   1 dnl $Id$
   2
   3 dnl Copyright (C) 2003 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18 dnl
  19 dnl
  20 dnl As a special exception to the GNU General Public License, if you
  21 dnl distribute this file as part of a program that contains a configuration
  22 dnl script generated by Autoconf, you may include it under the same
  23 dnl distribution terms that you use for the rest of that program.
  24 dnl
  25
  26 AC_PREREQ(2.57)
  27 AC_INIT(util-vserver, 0.27.190, enrico.scholz@informatik.tu-chemnitz.de)
  28 AC_CONFIG_SRCDIR([src/capchroot.c])
  29 AC_CONFIG_HEADER([config.h])
  30
  31 AM_INIT_AUTOMAKE([gnits dist-bzip2 subdir-objects])
  32 AM_MAINTAINER_MODE
  33
  34 # Checks for programs.
  35 AC_PROG_CXX
  36 AC_PROG_CC
  37 AC_PROG_INSTALL
  38 AC_PROG_LN_S
  39 dnl AC_PROG_RANLIB
  40 AC_PROG_LIBTOOL
  41 AM_PROG_CC_C_O
  42 ENSC_CXXCOMPILER
  43
  44 check_paths=$PATH:/sbin:/usr/sbin:/usr/local/sbin
  45 AC_PATH_PROGS(AWK,     [awk],     [awk],         [ $check_paths ])
  46 AC_PATH_PROGS(GREP,    [grep],    [grep],        [ $check_paths ])
  47 AC_PATH_PROGS(IP,      [ip],      [ip],          [ $check_paths ])
  48 AC_PATH_PROGS(MOUNT,   [mount],   [/bin/mount],  [ $check_paths ])
  49 AC_PATH_PROGS(UMOUNT,  [umount],  [/bin/umount], [ $check_paths ])
  50 AC_PATH_PROGS(NICE,    [nice],    [nice],        [ $check_paths ])
  51 AC_PATH_PROGS(VCONFIG, [vconfig], [vconfig],     [ $check_paths ])
  52 AC_PATH_PROGS(WC,      [wc],      [wc],          [ $check_paths ])
  53
  54
  55 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
  56 ENSC_CHECK_CXX_FLAG([-ansi   -Wall -pedantic -W -fmessage-length=0])
  57
  58 ENSC_FPIC_SYSCALL
  59
  60
  61 AC_MSG_CHECKING([whether to enable debug-code in library])
  62 AC_ARG_ENABLE([lib-debug],
  63               [AC_HELP_STRING([--enable-lib-debug],
  64                               [enable additional debug code in library (default: no)])],
  65               [case "$enableval" in
  66                   yes)  use_lib_debug=1;;
  67                   no)   use_lib_debug=;;
  68                   *)    AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
  69                esac],
  70               [ use_lib_debug= ])
  71
  72 if test x"$use_lib_debug" = x; then
  73         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
  74         AC_MSG_RESULT(no)
  75 else
  76         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
  77         AC_MSG_RESULT(yes)
  78 fi
  79
  80 AC_ARG_VAR(CC, [The C compiler])
  81
  82 ENSC_INITRDDIR(initrddir)
  83 ENSC_RELEASE(RELEASE_CPPFLAGS)
  84 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC)
  85 ENSC_KERNEL_HEADERS(kernelincludedir)
  86 ENSC_UV_VROOTDIR(vserverdir)
  87 ENSC_CHANGELOG([HEAD])
  88
  89 dnl Check whether to use external kernel headers
  90 AC_MSG_CHECKING([whether to use internal kernel headers])
  91 AC_ARG_ENABLE([internal-headers],
  92               [AC_HELP_STRING([--disable-internal-headers],
  93                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
  94               [case "$enableval" in
  95                   yes|no) ;;
  96                   *)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
  97                esac],
  98               [enable_internal_headers=yes])
  99
 100 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
 101 AC_MSG_RESULT([$enable_internal_headers])
 102
 103
 104 dnl Check for the APIs to be used
 105 AC_MSG_CHECKING([for supported APIs])
 106 AC_ARG_ENABLE([apis],
 107               [AC_HELP_STRING([--enable-apis=APIS],
 108                               [enable support for the given apis; possible values are: legacy,compat,v11,ALL (default: ALL)])],
 109               [],
 110               [enable_apis=ALL])
 111
 112 test x"$enable_apis" != xALL || enable_apis='legacy,compat,v11'
 113 old_IFS=$IFS
 114 IFS=,;
 115 for i in $enable_apis; do
 116         case "$i" in
 117                 compat) AC_DEFINE(VC_ENABLE_API_COMPAT, 1, [Enable support for compatibily syscall API]);;
 118                 legacy) AC_DEFINE(VC_ENABLE_API_LEGACY, 1, [Enable support for old, /proc parsing API]);;
 119                 v11)    AC_DEFINE(VC_ENABLE_API_V11,    1, [Enable support for API of vserver 1.1.x]);;
 120                 *)      AC_MSG_ERROR(['$i' is not a supported API]);;
 121         esac
 122 done
 123 IFS=$old_IFS
 124 AC_MSG_RESULT([$enable_apis])
 125
 126 AC_LANG_PUSH(C++)
 127 AC_CHECK_HEADERS([ext2fs/ext2fs.h], [],
 128   [AC_CHECK_HEADERS([linux/ext2_fs.h], [],
 129                     [AC_MSG_ERROR([Sorry, do not know, how to include 'ext2fs.h'])])])
 130 AC_LANG_POP
 131
 132 AC_CHECK_FUNCS([vserver])
 133 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
 134 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
 135
 136 dnl BIG HACK! Do some autodetection here!
 137 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
 138
 139 if false; then
 140         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
 141 fi
 142
 143 AH_BOTTOM([#include "compat.h"])
 144 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile])
 145 AC_OUTPUT