configure.ac

   1 dnl $Id$
   2
   3 dnl Copyright (C) 2003,2004 Enrico Scholz <enrico.scholz@informatik.tu-chemnitz.de>
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 2, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18 dnl
  19 dnl
  20 dnl As a special exception to the GNU General Public License, if you
  21 dnl distribute this file as part of a program that contains a configuration
  22 dnl script generated by Autoconf, you may include it under the same
  23 dnl distribution terms that you use for the rest of that program.
  24 dnl
  25
  26 AC_PREREQ(2.57)
  27 AC_INIT(util-vserver, 0.30.215, vserver@list.linux-vserver.org)
  28 AC_CONFIG_SRCDIR([src/capchroot.c])
  29 AC_CONFIG_HEADER([config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31
  32 AM_INIT_AUTOMAKE([1.9 gnits dist-bzip2 subdir-objects])
  33 AM_MAINTAINER_MODE
  34
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37
  38 AC_SUBST(GPG_KEY, "0xFFD316AC53ACA43A!")
  39
  40 # Checks for programs.
  41 AC_PROG_CXX
  42 AC_PROG_CC
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45 AM_PROG_CC_C_O
  46 PKG_PROG_PKG_CONFIG
  47 ENSC_CXXCOMPILER
  48 ENSC_C99COMPILER
  49 AM_PROG_MKDIR_P
  50
  51 ENSC_SET_SEARCHPATH([$PATH:/sbin:/usr/sbin:/usr/local/sbin])
  52 ENSC_PATHPROG_STANDARD_TOOLS
  53
  54 ENSC_PATHPROG(IP,        ip,,      [Usually, this tool is shipped in the 'iproute' or 'iproute2' package of your distribution])
  55 ENSC_PATHPROG(IPTABLES,  iptables)
  56 ENSC_PATHPROG(MODPROBE,  modprobe)
  57 ENSC_PATHPROG(NAMEIF,    nameif)
  58 ENSC_PATHPROG(NOHUP,     nohup)
  59 ENSC_PATHPROG(RMMOD,     rmmod)
  60 ENSC_PATHPROG(VCONFIG,   vconfig,, [See http://www.candelatech.com/~greear/vlan.html; usually this tool is shipped in the 'vconfig' or 'vlan' package of your distribution])
  61 ENSC_PATHPROG(WGET,      wget)
  62 ENSC_PATHPROG(IONICE,    ionice,  [],  [This is usually shipped in the 'util-linux(-ng)' or 'schedutils' package])
  63 ENSC_PATHPROG(FILE,      file,    [file])
  64 ENSC_PATHPROG(GZIP,      gzip,    [gzip])
  65 ENSC_PATHPROG(BZIP2,     bzip2,   [bzip2])
  66 ENSC_PATHPROG(CPIO,      cpio,    [cpio])
  67 ENSC_PATHPROG(RESTORE,   restore, [restore])
  68 ENSC_PATHPROG(RSYNC,     rsync,   [rsync])
  69 ENSC_PATHPROG(STRACE,    strace,  [strace])
  70 ENSC_PATHPROG(FSCK,      fsck)
  71 ENSC_PATHPROG(FIND,      find)
  72
  73 ENSC_PATHPROG(DOXYGEN,   doxygen,  [:])
  74 ENSC_PATHPROG(XSLTP,     xsltp,    [:])
  75 ENSC_PATHPROG(XSLTPROC,  xsltproc, [:])
  76
  77
  78 AM_CONDITIONAL(HAVE_XSLTP,    test "$XSLTP"    != ':')
  79 AM_CONDITIONAL(HAVE_XSLTPROC, test "$XSLTPROC" != ':')
  80
  81 if test x"$prefix" = x/; then
  82         prefix=
  83 fi
  84
  85 ENSC_CHECK_CC_FLAG([-std=c99 -Wall -pedantic -W])
  86 ENSC_CHECK_CXX_FLAG([-ansi   -Wall -pedantic -W -fmessage-length=0])
  87
  88 AC_MSG_CHECKING([whether to enable extra optimizations])
  89 AC_ARG_ENABLE([extra-optimizations],
  90               [AC_HELP_STRING([--disable-extra-optimizations],
  91                               [disable certain extra optimizations (default: no)])],
  92               [case "$enableval" in
  93                   (yes) use_extra_optimizations=1;;
  94                   (no)  use_extra_optimizations=;;
  95                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--disable-extra-optimizations']);;
  96                esac],
  97               [use_extra_optimizations=1])
  98
  99 if test x"$use_extra_optimizations" = x; then
 100         AC_MSG_RESULT(no)
 101 else
 102         AC_MSG_RESULT(yes)
 103         ENSC_CHECK_CC_FLAG([-funit-at-a-time])
 104         ENSC_CHECK_CXX_FLAG([-funit-at-a-time])
 105 fi
 106
 107 AC_MSG_CHECKING([whether to enable debug-code in library])
 108 AC_ARG_ENABLE([lib-debug],
 109               [AC_HELP_STRING([--enable-lib-debug],
 110                               [enable additional debug code in library (default: no)])],
 111               [case "$enableval" in
 112                   (yes) use_lib_debug=1;;
 113                   (no)  use_lib_debug=;;
 114                   (*)   AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-lib-debug']);;
 115                esac],
 116               [ use_lib_debug= ])
 117
 118 if test x"$use_lib_debug" = x; then
 119         AC_SUBST(LIB_DEBUG_CPPFLAGS, [-DNDEBUG])
 120         AC_MSG_RESULT(no)
 121 else
 122         AC_SUBST(LIB_DEBUG_CPPFLAGS, [])
 123         AC_MSG_RESULT(yes)
 124 fi
 125
 126 AC_MSG_CHECKING([whether to enable expensive tests])
 127 AC_ARG_ENABLE([expensive-tests],
 128               [AC_HELP_STRING([--enable-expensive-tests],
 129                               [disable tests which might be expensive on some systems (default: no)])],
 130               [case "$enableval" in
 131                  (yes|no)  use_expensive_tests=$enableval;;
 132                  (*)       AC_MSG_ERROR(['$enableval' is not a valid value for '--enable-expensive-tests']);;
 133                esac],
 134               [ use_expensive_tests=no ])
 135 AC_MSG_RESULT($use_expensive_tests)
 136
 137 AC_SUBST(ENSC_USE_EXPENSIVE_TESTS, "$use_expensive_tests")
 138
 139
 140 ENSC_CHECK_PERSONALITY_FLAGS
 141
 142 AC_ARG_VAR(CC, [The C compiler])
 143
 144 ENSC_INITRDDIR(initrddir)
 145 ENSC_RELEASE(RELEASE_CPPFLAGS)
 146
 147 # HACK: This needs to be before ENSC_DIETLIBC_NEED_COMPAT, or the alternative
 148 # syscalls will never be enabled for glibc.
 149 ENSC_SYSCALLNR(vserver,273,[lib/syscall-fallback.h])
 150 ENSC_SYSCALL
 151
 152 dnl ###########################
 153 dnl
 154 dnl {some dietlibc related tests
 155 dnl
 156
 157 case $host_cpu in
 158         (i*86|athlon)   min_diet_ver=0.25;;
 159         (ia64|hppa*)    min_diet_ver=0.29;;
 160         (sparc*)        min_diet_ver=0.30;;
 161         (x86_64)        min_diet_ver=0.27;;
 162         (*)             min_diet_ver=0.28;;
 163 esac
 164
 165 ENSC_ENABLE_DIETLIBC(USE_DIETLIBC, [$min_diet_ver])
 166
 167 if test x"$ensc_have_dietlibc" = xno; then
 168         AC_MSG_WARN([***                                                         ***])
 169         AC_MSG_WARN([*** it is strongly recommended to link util-vserver against ***])
 170         AC_MSG_WARN([*** dietlibc;  glibc's NSS functions are very unreliable in ***])
 171         AC_MSG_WARN([*** chroot() environments,  so you have to  expect problems ***])
 172         AC_MSG_WARN([*** there.                                                  ***])
 173         AC_MSG_WARN([***                                                         ***])
 174         AM_CONDITIONAL(USE_DIETLIBC_COMPAT, false)
 175 else
 176         # HACK: libtool does not have cmdline options to build only
 177         # dynamic libraries; this can be done with the
 178         # '--disable-static' ./configure option only.  As our static
 179         # libraries will be build with dietlibc, we have to do set
 180         # this option which is evaluated by 'AC_PROG_LIBTOOL'
 181         # below.  Therefore, this macro must not be called earlier.
 182         enable_static=no
 183
 184         ENSC_DIETLIBC_NEED_COMPAT(USE_DIETLIBC_COMPAT)
 185 fi
 186
 187 AM_CONDITIONAL(ENSC_USE_DIETLIBC, test x"$ensc_have_dietlibc" = xyes)
 188 AM_CONDITIONAL(ENSC_USE_GLIBC,    true)
 189
 190 # HACK: see comments at 'enable_static' above
 191 AC_PROG_LIBTOOL
 192 dnl
 193 dnl dietlibc stuff ends here}
 194 dnl
 195 dnl ##########################
 196
 197
 198 ENSC_UV_VROOTDIR(vserverdir)
 199 ENSC_CHANGELOG
 200
 201
 202 dnl ##########################
 203 dnl
 204 dnl {Check whether to use external kernel headers
 205 dnl
 206 AC_MSG_CHECKING([whether to use internal kernel headers])
 207 AC_ARG_ENABLE([internal-headers],
 208               [AC_HELP_STRING([--disable-internal-headers],
 209                               [use vserver specific headers from the kernel instead of the shipped versions (default: no)])],
 210               [case "$enableval" in
 211                   (yes|no) ;;
 212                   (*)      AC_MSG_ERROR(['$i' is not a supported value for '--disable-internal-headers']);;
 213                esac],
 214               [enable_internal_headers=yes])
 215
 216 AM_CONDITIONAL(ENSC_ENABLE_INTERNAL_HEADERS, [test x"$enable_internal_headers" = xyes])
 217 AC_MSG_RESULT([$enable_internal_headers])
 218 dnl
 219 dnl the check regarding external kernel headers ends here}
 220 dnl
 221 dnl ##########################
 222
 223 dnl ##########################
 224 dnl
 225 dnl {Check for the APIs to be used
 226 dnl
 227 AH_TEMPLATE(VC_ENABLE_API_COMPAT,   [Enable support for compatibility syscall API])
 228 AH_TEMPLATE(VC_ENABLE_API_LEGACY,   [Enable support for old, /proc parsing API])
 229 AH_TEMPLATE(VC_ENABLE_API_V11,      [Enable support for API of vserver 1.1.x])
 230 AH_TEMPLATE(VC_ENABLE_API_FSCOMPAT, [Enable support for filesystem compatibility API])
 231 AH_TEMPLATE(VC_ENABLE_API_V13OBS,   [Enable support for some obsoleted API of vserver 1.3.x])
 232 AH_TEMPLATE(VC_ENABLE_API_V13,      [Enable support for API of vserver 1.3.x])
 233 AH_TEMPLATE(VC_ENABLE_API_NET,      [Enable support for network context API])
 234 AH_TEMPLATE(VC_ENABLE_API_V21,      [Enable support for API of vserver 2.1.x])
 235 AH_TEMPLATE(VC_ENABLE_API_V22,      [Enable support for API of vserver 2.2.x])
 236 AH_TEMPLATE(VC_ENABLE_API_V23,      [Enable support for API of vserver 2.3.x])
 237 AH_TEMPLATE(VC_ENABLE_API_NETV2,    [Enable support for new networking API])
 238 AH_TEMPLATE(VC_ENABLE_API_OLDPROC,  [Enable API for a backward compatible /proc parsing])
 239 AH_TEMPLATE(VC_ENABLE_API_OLDUTS,   [Enable API for a backward compatible uts handling])
 240
 241 AC_MSG_CHECKING([for supported APIs])
 242 AC_ARG_ENABLE([apis],
 243               [AC_HELP_STRING([--enable-apis=APIS],
 244                               [enable support for the given apis; possible values are: legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2 ALL,NOLEGACY (default: v13,net,v21,v22,v23,netv2)])],
 245               [],
 246               [enable_apis=v13,net,v21,v22,v23,netv2])
 247
 248 test x"$enable_apis" != xALL      || enable_apis='legacy,compat,v11,fscompat,v13obs,v13,net,v21,v22,v23,netv2'
 249 test x"$enable_apis" != xNOLEGACY || enable_apis='compat,v11,fscompat,v13,net,v21,v22,v23,netv2'
 250 enable_api_oldproc=
 251 enable_api_olduts=
 252
 253 echo $enable_apis | sed 's/,/\n/g' | while read i; do
 254         case "$i" in
 255                 (compat)        AC_DEFINE(VC_ENABLE_API_COMPAT,   1)
 256                                 enable_api_oldproc=${enable_api_oldproc:-1}
 257                                 enable_api_olduts=${enable_api_olduts:-1}
 258                                 ;;
 259                 (legacy)        AC_DEFINE(VC_ENABLE_API_LEGACY,   1)
 260                                 enable_api_oldproc=${enable_api_oldproc:-1}
 261                                 enable_api_olduts=${enable_api_olduts:-1}
 262                                 ;;
 263                 (v11)           AC_DEFINE(VC_ENABLE_API_V11,      1)
 264                                 enable_api_oldproc=${enable_api_oldproc:-1}
 265                                 enable_api_olduts=${enable_api_olduts:-1}
 266                                 ;;
 267                 (fscompat)      AC_DEFINE(VC_ENABLE_API_FSCOMPAT, 1);;
 268                 (v13obs)        AC_DEFINE(VC_ENABLE_API_V13OBS,   1)
 269                                 AC_DEFINE(VC_ENABLE_API_V13,      1);;
 270                 (v13)           AC_DEFINE(VC_ENABLE_API_V13,      1);;
 271                 (net)           AC_DEFINE(VC_ENABLE_API_NET,      1);;
 272                 (v21)           AC_DEFINE(VC_ENABLE_API_V21,      1);;
 273                 (v22)           AC_DEFINE(VC_ENABLE_API_V22,      1);;
 274                 (v23)           AC_DEFINE(VC_ENABLE_API_V23,      1);;
 275                 (netv2)         AC_DEFINE(VC_ENABLE_API_NETV2,    1);;
 276                 (oldproc)       enable_api_oldproc=2;;
 277                 (olduts)        enable_api_olduts=2;;
 278                 (*)             AC_MSG_ERROR(['$i' is not a supported API]);;
 279         esac
 280 done
 281 if test x"$enable_api_oldproc" != x; then
 282         AC_DEFINE(VC_ENABLE_API_OLDPROC, 1)
 283         test x"$enable_api_oldproc" != x2 && enable_apis="$enable_apis,oldproc"
 284 fi
 285 if test x"$enable_api_olduts" != x; then
 286         AC_DEFINE(VC_ENABLE_API_OLDUTS, 1)
 287         test x"$enable_api_olduts" != x2 && enable_apis="$enable_apis,olduts"
 288 fi
 289 AC_MSG_RESULT([$enable_apis])
 290 dnl
 291 dnl the check for used APIs ends here}
 292 dnl
 293 dnl ##########################
 294
 295
 296 ENSC_CHECK_EXT2FS_HEADER
 297 AC_CHECK_FUNCS([vserver])
 298 AC_CHECK_DECLS(MS_MOVE,,,[#include <linux/fs.h>])
 299 AC_CHECK_TYPES(xid_t,,,[#include <sys/types.h>])
 300 AC_CHECK_TYPES(nid_t,,,[#include <sys/types.h>])
 301 AC_CHECK_TYPES(tag_t,,,[#include <sys/types.h>])
 302
 303 AC_CHECK_HEADERS([sys/capability.h])
 304
 305 dnl vlogin might need -lutil
 306 if test x"$ensc_have_dietlibc" = xno; then
 307         AC_CHECK_FUNC([openpty],, [AC_CHECK_LIB([util], [openpty],, [AC_MSG_ERROR([
 308 ****
 309 **** openpty could not be found
 310 ****])])])
 311 fi
 312
 313
 314 dnl ########################
 315 dnl
 316 dnl {crypto stuff
 317 dnl
 318 AC_ARG_WITH(crypto-api,
 319             AC_HELP_STRING([--with-crypto-api=API],
 320                            [select crypto api to be used; possible values are `none', `nss', `beecrypt', `auto' (default:auto)]),
 321             [case $withval in
 322                 (none|nss|beecrypt|auto)        ensc_crypto_api=$withval;;
 323                 (yes)                           ensc_crypto_api=auto;;
 324                 (no)                            ensc_crypto_api=none;;
 325                 (*)     AC_MSG_ERROR([invalid crypto-api value, only none,nss,beecrypt,auto are supported]);;
 326              esac],[ensc_crypto_api=auto])
 327
 328
 329 dnl Now, check for matching crypto api. When selected 'auto', the
 330 dnl first matching one wins
 331
 332 dnl ########################
 333 dnl
 334 dnl {check for beecrypt
 335 dnl
 336 case $ensc_crypto_api in
 337 (auto|beecrypt)
 338 if test x"$ensc_cv_c99_c99compiler" = xyes; then
 339         ensc_have_beecrypt=yes
 340
 341         if test x"$ensc_have_beecrypt" = xyes; then
 342                 AC_CHECK_HEADER([beecrypt/beecrypt.h], [ : ],
 343                                 [ ensc_have_beecrypt=no ])
 344         fi
 345
 346         if test x"$ensc_have_beecrypt" = xyes; then
 347                 AC_CHECK_LIB(beecrypt, hashFunctionContextInit, [ : ],
 348                              [ ensc_have_beecrypt=no ])
 349         fi
 350 else
 351         ensc_have_beecrypt=no
 352 fi;;
 353 esac
 354
 355 case $ensc_crypto_api in
 356 (auto)          if test x"$ensc_have_beecrypt"  = xyes; then
 357                         AC_MSG_NOTICE([using beecrypt as crypto api])
 358                         ensc_crypto_api=beecrypt
 359                 fi;;
 360 (beecrypt)      if test x"$ensc_have_beecrypt" != xyes; then
 361                         AC_MSG_ERROR([beecrypt crypto api not found])
 362                 fi;;
 363 esac
 364
 365 AM_CONDITIONAL(ENSC_HAVE_BEECRYPT, test x"$ensc_have_beecrypt" = xyes)
 366 AM_CONDITIONAL(ENSC_CAN_BEECRYPT_WITH_DIETLIBC, false)
 367 dnl
 368 dnl beecrypt stuff ends here}
 369 dnl
 370 dnl ########################
 371
 372
 373 dnl ########################
 374 dnl
 375 dnl {check for nss
 376 dnl
 377
 378 case $ensc_crypto_api in
 379 (nss)   PKG_CHECK_MODULES(NSS, nss);;
 380 (auto)  PKG_CHECK_MODULES(NSS, nss, [
 381                 AC_MSG_NOTICE([using NSS as crypto api])
 382                 ensc_crypto_api=nss]);;
 383 esac
 384
 385 dnl
 386 dnl nss stuff ends here}
 387 dnl
 388 dnl ########################
 389
 390 case $ensc_crypto_api in
 391 (beecrypt)
 392         ENSC_HAVE_CRYPTO=true
 393         ENSC_CRYPTO_API=ENSC_CRYPTO_API_BEECRYPT
 394         ENSC_CRYPTO_CFLAGS=
 395         ENSC_CRYPTO_LIB=-lbeecrypt
 396         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
 397         ;;
 398
 399 (nss)
 400         ENSC_HAVE_CRYPTO=true
 401         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NSS
 402         ENSC_CRYPTO_CFLAGS=$NSS_CFLAGS
 403         ENSC_CRYPTO_LIB=$NSS_LIBS
 404         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
 405         ;;
 406
 407 (none|auto)
 408         ENSC_HAVE_CRYPTO=false
 409         ENSC_CRYPTO_API=ENSC_CRYPTO_API_NONE
 410         ENSC_CRYPTO_CFLAGS=
 411         ENSC_CRYPTO_LIB=
 412         ENSC_CAN_CRYPTO_WITH_DIETLIBC=false
 413
 414         AC_MSG_WARN([No crypto api found/select. This will disable the build of 'vhashify'])
 415         ;;
 416
 417 (*)     AC_MSG_ERROR([internal error])
 418 esac
 419
 420 AM_CONDITIONAL(ENSC_HAVE_CRYPTO, $ENSC_HAVE_CRYPTO)
 421 AM_CONDITIONAL(ENSC_CAN_CRYPTO_WITH_DIETLIBC, $ENSC_CAN_CRYPTO_WITH_DIETLIBC)
 422 AC_SUBST(ENSC_CRYPTO_CFLAGS, $ENSC_CRYPTO_CFLAGS)
 423 AC_SUBST(ENSC_CRYPTO_LIB,    $ENSC_CRYPTO_LIB)
 424 AC_DEFINE_UNQUOTED(ENSC_CRYPTO_API, $ENSC_CRYPTO_API, [Used crypto API])
 425
 426 dnl
 427 dnl crypto stuff ends here}
 428 dnl
 429 dnl ########################
 430
 431
 432 dnl Check what distro this is, use Gentoo initscripts if appropriate
 433 AC_MSG_CHECKING([for host initscripts])
 434 AC_ARG_WITH(initscripts, AC_HELP_STRING([--with-initscripts=TYPE], [force host initscripts; valid values are 'gentoo' and 'sysv' (default: guess)]), [
 435         case "$withval" in
 436         gentoo) ensc_with_init=gentoo;;
 437         sysv)   ensc_with_init=sysv;;
 438         *)      AC_MSG_ERROR([invalid initscripts value, only gentoo and sysv are supported]);;
 439         esac
 440         ], [
 441         if test -e /etc/gentoo-release; then
 442                 ensc_with_init=gentoo
 443         else
 444                 ensc_with_init=sysv
 445         fi
 446         ])
 447 AC_MSG_RESULT([$ensc_with_init])
 448 AM_CONDITIONAL(HAVE_GENTOO_INIT, test x"$ensc_with_init" = xgentoo)
 449 AM_CONDITIONAL(HAVE_SYSV_INIT, test x"$ensc_with_init" = xsysv)
 450
 451
 452 dnl ########################
 453 dnl Check for Python
 454
 455 ensc_have_python=yes
 456 AM_PATH_PYTHON([2.4],, [:])
 457 if test "x$PYTHON" = x:; then
 458         ensc_have_python=no
 459 fi
 460 if test x$ensc_have_python = xyes; then
 461         PYTHON_CFLAGS=-I`$PYTHON -c 'from distutils.sysconfig import get_python_inc; print(get_python_inc(1))'`
 462         PYTHON_LDFLAGS=-L`$PYTHON -c 'from distutils.sysconfig import get_python_lib; print(get_python_lib(1))'`
 463         AC_SUBST(PYTHON_CFLAGS)
 464         AC_SUBST(PYTHON_LDFLAGS)
 465 else
 466         ensc_have_python=no
 467 fi
 468 AC_PATH_PROG([CTAGS], [ctags], [no])
 469 if test "x$CTAGS" = xno; then
 470         ensc_have_python=no
 471 fi
 472 AM_CONDITIONAL([HAVE_PYTHON], [test x$ensc_have_python = xyes])
 473
 474 dnl Python stuff ends here
 475 dnl ########################
 476
 477
 478 dnl ########################
 479 dnl Library versioning
 480
 481 ensc_have_versioning=yes
 482 AC_ARG_ENABLE(versioning, AC_HELP_STRING([--disable-versioning], [Disable library versioning]), [ensc_have_versioning="$enableval"])
 483 AM_CONDITIONAL([HAVE_VERSIONING], [test "x$ensc_have_versioning" = xyes])
 484 if test "x$ensc_have_versioning" = xyes; then
 485         AC_DEFINE([HAVE_VERSIONING], [1], [Define this to use library versioning])
 486 fi
 487
 488 dnl /Library versioning
 489 dnl ########################
 490
 491
 492 dnl BIG HACK! Do some autodetection here!
 493 AC_DEFINE(UTMP_GID, [22], [The utmp gid-number])
 494
 495 if false; then
 496         AC_DEFINE(HAVE_GROWING_STACK, [1], [Define to 1 if the stack is on growing addresses])
 497 fi
 498
 499 AC_DEFINE(_FILE_OFFSET_BITS, [64], [Use 64bit interface for filesystem operations])
 500
 501 dnl ########################
 502 dnl
 503 dnl {The final info-page
 504 dnl
 505 ensc_cxx_affected=" (affected: vbuild, vcheck)"
 506 ensc_c99_affected=" (affected: vunify, vcopy, vhashify, vdlimit)"
 507 ensc_diet_msg=" (you have been warned)"
 508 ensc_diet_version_msg=" ($ensc_version_dietlibc)"
 509 ensc_diet_compat_msg=" (using -lcompat)"
 510 test x"$ensc_cv_cxx_cxxcompiler"    = xno || ensc_cxx_affected=
 511 test x"$ensc_cv_c99_c99compiler"    = xno || ensc_c99_affected=
 512 test x"$ensc_have_dietlibc"         = xno || ensc_diet_msg=
 513 test x"$ensc_version_dietlibc"     != x   || ensc_diet_version_msg=
 514 test x"$ensc_have_dietlibc$ensc_cv_c_dietlibc_compat" = xyesyes || ensc_diet_compat_msg=
 515
 516 AH_BOTTOM([#include "compat.h"
 517 ])
 518 AC_CONFIG_COMMANDS_PRE([
 519                         FEATURES_TXT="\
 520 Features:
 521                        CC: $CC, $($CC   --version | sed -e '1p;d')
 522                       CXX: $CXX, $($CXX --version | sed -e '1p;d')
 523                  CPPFLAGS: '$CPPFLAGS'
 524                    CFLAGS: '$CFLAGS'
 525                  CXXFLAGS: '$CXXFLAGS'
 526                build/host: $build/$host
 527              Use dietlibc: $ensc_have_dietlibc$ensc_diet_version_msg$ensc_diet_msg$ensc_diet_compat_msg
 528        Build C++ programs: $ensc_cv_cxx_cxxcompiler$ensc_cxx_affected
 529        Build C99 programs: $ensc_cv_c99_c99compiler$ensc_c99_affected
 530            Available APIs: $enable_apis
 531             ext2fs Source: $ensc_cv_test_ext2fs_header
 532     syscall(2) invocation: $with_syscall
 533       vserver(2) syscall#: $ensc_cv_value_syscall_vserver
 534                crypto api: $ensc_crypto_api
 535           python bindings: $ensc_have_python
 536    use library versioning: $ensc_have_versioning
 537
 538 Paths:
 539                    prefix: $prefix
 540         sysconf-Directory: $sysconfdir
 541             cfg-Directory: $sysconfdir/vservers
 542          initrd-Directory: $initrddir
 543        pkgstate-Directory: $localstatedir/run/vservers
 544           vserver-Rootdir: $vserverdir
 545 "
 546                         echo "$FEATURES_TXT" >FEATURES.txt
 547                         ])
 548 dnl
 549 dnl final info-page ends here}
 550 dnl
 551 dnl ########################
 552
 553 AC_CONFIG_FILES([util-vserver.spec Makefile distrib/Makefile lib/apidoc/Doxyfile])
 554 AC_OUTPUT
 555
 556 AC_MSG_NOTICE([
 557
 558 $PACKAGE_STRING
 559
 560 $FEATURES_TXT])